wok annotate BootProg/stuff/boot32.asm @ rev 25857

Fix reset menu.xml symlink when upgrade slitaz-configs
author Stanislas Leduc <shann@slitaz.org>
date Thu Aug 07 17:10:52 2025 +0000 (5 weeks ago)
parents 7db7b7aaf63e
children
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24535 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24535 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@25460 20 ;; Its maximum size can be up to 637KB without Extended BIOS Data area. ;;
pascal@24476 21 ;; ;;
pascal@24476 22 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@25705 23 ;; ("No bootfile" or "Read error") ;;
pascal@24476 24 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 25 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; ;;
pascal@25564 28 ;; Known Limitation: ;;
pascal@25564 29 ;; ~~~~~~~~~~~~~~~~~ ;;
pascal@25564 30 ;; - Need a up to date field bpbHiddenSectors to work in a partition ; ;;
pascal@25564 31 ;; most formatters don't update it correcly in extended partitions. ;;
pascal@25564 32 ;; ;;
pascal@25564 33 ;; - Requires i80386 or better CPU. ;;
pascal@25564 34 ;; ;;
pascal@25564 35 ;; ;;
pascal@24476 36 ;; Known Bugs: ;;
pascal@24476 37 ;; ~~~~~~~~~~~ ;;
pascal@24476 38 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 39 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 40 ;; ;;
pascal@24476 41 ;; ;;
pascal@24476 42 ;; Memory Layout: ;;
pascal@24476 43 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 44 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 45 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 46 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 47 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 48 ;; ;;
pascal@24476 49 ;; physical address ;;
pascal@24476 50 ;; +------------------------+ 00000H ;;
pascal@24476 51 ;; | Interrupt Vector Table | ;;
pascal@24476 52 ;; +------------------------+ 00400H ;;
pascal@24476 53 ;; | BIOS Data Area | ;;
pascal@24476 54 ;; +------------------------+ 00500H ;;
pascal@24476 55 ;; | PrtScr Status / Unused | ;;
pascal@24476 56 ;; +------------------------+ 00600H ;;
pascal@24476 57 ;; | Loaded Image | ;;
pascal@24476 58 ;; +------------------------+ nnnnnH ;;
pascal@24476 59 ;; | Available Memory | ;;
pascal@25460 60 ;; +------------------------+ A0000H - 1KB ;;
pascal@24476 61 ;; | Boot Sector | ;;
pascal@25460 62 ;; +------------------------+ A0000H - 0.5KB ;;
pascal@25460 63 ;; | 0.5KB Boot Stack | ;;
pascal@24476 64 ;; +------------------------+ A0000H ;;
pascal@24476 65 ;; | Video RAM | ;;
pascal@24476 66 ;; ;;
pascal@24476 67 ;; ;;
pascal@24476 68 ;; Boot Image Startup (register values): ;;
pascal@24476 69 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 70 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 71 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 72 ;; cs:ip = program entry point ;;
pascal@24476 73 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 74 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 75 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 76 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 77 ;; Magic numbers: ;;
pascal@24476 78 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 79 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 80 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 81 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 82 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 83 ;; metal and MS-DOS programs. ;;
pascal@24945 84 ;; The command line contains no arguments. ;;
pascal@24476 85 ;; ;;
pascal@24476 86 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 87
pascal@24491 88 %define bx(label) bx+label-boot
pascal@25449 89 %define si(label) si+label-boot
pascal@25485 90 ExtraBootSector equ 1
pascal@25449 91 ClusterMask equ 1 ; +9 bytes
pascal@25460 92 NullEntryCheck equ 1 ; +5 bytes
pascal@25572 93 CheckAttrib equ 0 ; +6 bytes
pascal@25569 94 NonMirroredFATs equ 1 ; +20 bytes
pascal@25569 95 ReadRetry equ 1 ; +6/7 bytes
pascal@25569 96 LBA48bits equ 1 ; +10 bytes
pascal@25569 97 CHSsupport equ 1 ; +35 bytes max 8GB
pascal@25569 98 CHSgeometryCheck equ 1 ; +20 bytes
pascal@25569 99 CHSsanityCheck equ 1 ; +9 bytes
pascal@25569 100 SectorOf512Bytes equ 0 ; -4 bytes
pascal@25458 101 Always2FATs equ 0 ; -4 bytes
pascal@25564 102 WaitForKey equ 0 ; +5 bytes
pascal@25699 103 AnyWhere equ 1 ; +3 bytes
pascal@25706 104 Int21h equ 1 ; +70 bytes
pascal@24491 105
pascal@24476 106 [BITS 16]
pascal@25564 107 [CPU 386]
pascal@24476 108
pascal@24478 109 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@25460 110 StackSize equ 512
pascal@24476 111
pascal@24476 112 [SECTION .text]
pascal@24476 113 [ORG 0]
pascal@24476 114
pascal@24476 115 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 116 ;; Boot sector starts here ;;
pascal@24476 117 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 118
pascal@24491 119 boot:
pascal@25458 120 DriveNumber equ boot+0
pascal@25458 121 HiLBA equ boot+2
pascal@24476 122 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 123 nop
pascal@24476 124 bsOemName DB "BootProg" ; 0x03
pascal@24476 125
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 127 ;; BPB1 starts here ;;
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 129
pascal@25564 130 bpbBytesPerSector DW 0 ; 0x0B 512, 1024, 2048 or 4096
pascal@25564 131 bpbSectorsPerCluster DB 0 ; 0x0D 1, 2, 4, 8, 16, 32, 64 or 128
pascal@25564 132 bpbReservedSectors DW 0 ; 0x0E 32
pascal@25564 133 bpbNumberOfFATs DB 0 ; 0x10 2
pascal@25564 134 bpbRootEntries DW 0 ; 0x11 0
pascal@25564 135 bpbTotalSectors DW 0 ; 0x13 0
pascal@25564 136 bpbMedia DB 0 ; 0x15 F8, F0
pascal@25564 137 bpbSectorsPerFAT DW 0 ; 0x16 0
pascal@24479 138 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 139 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 140 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 141 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 142
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 144 ;; BPB1 ends here ;;
pascal@24476 145 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; BPB2 starts here ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24479 151 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 152 bsExtendedFlags DW 0 ; 0x28
pascal@24479 153 bsFSVersion DW 0 ; 0x2A
pascal@24479 154 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 155 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 156 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 157 bsreserved times 12 DB 0 ; 0x34
pascal@24479 158 bsDriveNumber DB 0 ; 0x40
pascal@24479 159 bsreserved1 DB 0 ; 0x41
pascal@25564 160 bsExtendedBootSignature DB 0 ; 0x42 29
pascal@24479 161 bsVolumeSerialNumber DD 0 ; 0x43
pascal@25458 162 bsVolumeLabel times 11 DB " " ; 0x47 "NO NAME "
pascal@25458 163 bsFileSystemName times 8 DB " " ; 0x52 "FAT32 "
pascal@24476 164
pascal@24476 165 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 166 ;; BPB2 ends here ;;
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 168
pascal@25706 169 %macro Abort 1
pascal@25706 170 call Error
pascal@25706 171 db %1
pascal@25706 172 db '.'
pascal@25706 173 %if Int21h
pascal@25706 174 db '$'
pascal@25706 175 %endif
pascal@25706 176 %endm
pascal@25706 177
pascal@24476 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 179 ;; Boot sector code starts here ;;
pascal@24476 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 181
pascal@24476 182 start:
pascal@24476 183
pascal@24476 184 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 185 ;; How much RAM is there? ;;
pascal@24476 186 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 187
pascal@25699 188 int 12h ; get conventional memory size (in KBs)
pascal@25698 189 %if AnyWhere
pascal@25698 190 call here
pascal@25698 191 here:
pascal@25698 192 pop si
pascal@25699 193 sub si, here - boot - 2 ; exclude DriveNumber
pascal@25698 194 %endif
pascal@25699 195 dec ax ; reserve 1K bytes for the code and the stack
pascal@24525 196 mov cx, 106h
pascal@25699 197 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 198
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 202
pascal@25699 203 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@25705 204 %if ExtraBootSector != 0
pascal@25705 205 add al, 32
pascal@25705 206 %else
pascal@24525 207 mov ss, ax
pascal@24525 208 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@25485 209 %endif
pascal@24476 210
pascal@24476 211 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 212 ;; Copy ourselves to top of memory ;;
pascal@24476 213 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 214
pascal@25698 215 xor di, di
pascal@25698 216 %if AnyWhere == 0
pascal@25699 217 mov si, 7C02h ; exclude DriveNumber
pascal@24476 218 mov ds, di
pascal@25698 219 %endif
pascal@25449 220 push es
pascal@25698 221 cld
pascal@25699 222 xchg ax, dx
pascal@25699 223 stosw ; store BIOS boot drive number
pascal@25699 224 %if AnyWhere
pascal@25699 225 rep cs movsw ; move 512 bytes (+ 12)
pascal@25699 226 %else
pascal@25699 227 rep movsw ; move 512 bytes (+ 12)
pascal@25699 228 %endif
pascal@24476 229
pascal@24476 230 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 231 ;; Jump to the copy ;;
pascal@24476 232 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 233
pascal@25486 234 %if ExtraBootSector != 0
pascal@25486 235 push word main
pascal@25486 236 %else
pascal@25450 237 push byte main
pascal@25486 238 %endif
pascal@24476 239 retf
pascal@24476 240
pascal@25486 241 %if ExtraBootSector != 0
pascal@25486 242 %macro MovedCode 0
pascal@24476 243 main:
pascal@25703 244 push dx
pascal@25699 245 %else
pascal@25699 246 main:
pascal@25564 247 %endif
pascal@25564 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 249 ;; Get drive parameters ;;
pascal@25564 250 ;; Update heads count ;;
pascal@25564 251 ;; for current BIOS ;;
pascal@25564 252 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 253
pascal@25564 254 %if CHSgeometryCheck != 0
pascal@25564 255 mov ah, 8 ; update AX,BL,CX,DX,DI, and ES registers
pascal@25564 256 int 13h ; may destroy SI,BP, and DS registers
pascal@25564 257 %endif
pascal@25564 258 push cs
pascal@25564 259 pop ds
pascal@25564 260 xor ebx, ebx
pascal@25564 261
pascal@25564 262 %if CHSgeometryCheck != 0
pascal@25564 263 and cx, byte 3Fh
pascal@25564 264 je BadParams ; verify updated and validity
pascal@25564 265 mov [bx(bpbSectorsPerTrack)], cx
pascal@25564 266 mov cl, dh
pascal@25564 267 inc cx
pascal@25564 268 mov [bx(bpbHeadsPerCylinder)], cx
pascal@25564 269 xor cx, cx
pascal@25564 270 BadParams:
pascal@25564 271 %endif
pascal@25564 272 %if ExtraBootSector != 0
pascal@25564 273 pop es
pascal@25564 274 mul ebx ; edx:eax = 0
pascal@25564 275 inc ax
pascal@25485 276 call ReadSectorBoot
pascal@25485 277 push ds
pascal@25485 278 pop ss
pascal@25485 279 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@25485 280 %endif
pascal@24476 281
pascal@25706 282 %if Int21h
pascal@25706 283 mov ax, 3521h
pascal@25706 284 mov dx, Int21xx
pascal@25706 285 pushf
pascal@25706 286 push cs
pascal@25706 287 call dx
pascal@25706 288 %endif
pascal@25706 289
pascal@25449 290 %if ClusterMask != 0
pascal@24491 291 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@25449 292 %endif
pascal@24491 293 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 294
pascal@24478 295 push byte ImageLoadSeg
pascal@24478 296 pop es
pascal@25449 297
pascal@25449 298 RootDirReadContinue:
pascal@25458 299 call ReadClusterSector ; read one sector of the root dir
pascal@24476 300
pascal@24476 301 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 302 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 304
pascal@24476 305 xor di, di ; es:di -> root entries array
pascal@24476 306
pascal@24476 307 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 308 ;; Looks for a file/dir by its name ;;
pascal@24476 309 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 310 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 311 ;; ES:DI -> root directory array ;;
pascal@24525 312 ;; BP = paragraphs in sector ;;
pascal@24476 313 ;; Output: ESI = cluster number ;;
pascal@24476 314 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 315
pascal@24476 316 FindNameCycle:
pascal@25449 317 %if NullEntryCheck != 0
pascal@24525 318 cmp byte [es:di], bh
pascal@24478 319 je ErrFind ; end of root directory (NULL entry found)
pascal@25449 320 %endif
pascal@24478 321 pusha
pascal@25454 322 mov cl, NameLength
pascal@24525 323 mov si, ProgramName ; ds:si -> program name
pascal@24476 324 repe cmpsb
pascal@25467 325 VolumeLabel equ 8
pascal@25467 326 SubDirectory equ 10h
pascal@25564 327 %if CheckAttrib != 0
pascal@25467 328 jnz SkipFindName
pascal@25467 329 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 330 SkipFindName:
pascal@25467 331 %endif
pascal@24525 332 je FindNameFound
pascal@24478 333 popa
pascal@24525 334 add di, byte 32
pascal@24476 335 dec bp
pascal@24476 336 dec bp
pascal@24476 337 jnz FindNameCycle ; next root entry
pascal@25458 338 loop RootDirReadContinue ; next sector in cluster
pascal@25458 339 cmp esi, 0FFFFFF6h ; carry=0 if last cluster, and carry=1 otherwise
pascal@25458 340 jnc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 341 ErrFind:
pascal@25706 342 Abort "No bootfile" ; end of root directory (dir end reached)
pascal@25564 343 %if ExtraBootSector != 0
pascal@25564 344 %endm
pascal@25564 345 %macro BootFileName 0
pascal@25564 346 %endif
pascal@24476 347 FindNameFound:
pascal@24525 348 push word [es:di+14h-11]
pascal@24525 349 push word [es:di+1Ah-11]
pascal@24478 350 pop esi ; esi = cluster no. cx = 0
pascal@24476 351
pascal@24525 352 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 353 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 354
pascal@24476 355 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 356 ;; Load the entire file ;;
pascal@24476 357 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 358
pascal@24476 359 push es
pascal@24476 360 FileReadContinue:
pascal@24476 361 push di
pascal@25458 362 call ReadClusterSector ; read one sector of the boot file
pascal@25458 363 dec cx
pascal@24476 364 mov di, es
pascal@24478 365 add di, bp
pascal@24478 366 mov es, di ; es:bx updated
pascal@24476 367 pop di
pascal@24478 368
pascal@24476 369 sub di, bp
pascal@24476 370 jae FileReadContinue
pascal@24943 371 xor ax, ax
pascal@24476 372 pop bp
pascal@24476 373
pascal@24476 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 375 ;; Type detection, .COM or .EXE? ;;
pascal@24476 376 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 377
pascal@24476 378 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24535 379
pascal@24476 380 add bp, [bx+08h] ; bp = image base
pascal@24476 381 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 382
pascal@24476 383 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 384 je RelocateEXE ; yes, it's an EXE program
pascal@24476 385
pascal@24476 386 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 387 ;; Setup and run a .COM program ;;
pascal@24535 388 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 389 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 390 ;; cmdline=void ;;
pascal@24476 391 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 392
pascal@24535 393 mov di, 100h ; ip
pascal@24476 394 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 395 mov ss, bp
pascal@24476 396 xor sp, sp
pascal@24476 397 push bp ; cs, ds and es
pascal@25486 398 jmp short Run
pascal@25706 399
pascal@25706 400 %if Int21h
pascal@25706 401 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25706 402 ;; DOS service ah=02h,09h,25h,35h ;;
pascal@25706 403 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25706 404
pascal@25706 405 Int21xx:
pascal@25706 406 cld
pascal@25706 407 push si
pascal@25706 408 mov si, dx
pascal@25706 409 push ds
pascal@25706 410 push ax
pascal@25706 411 xchg al, ah
pascal@25706 412 push bx
pascal@25706 413 xor bx, bx
pascal@25706 414 cmp al, 09h
pascal@25706 415 je putslp
pascal@25706 416 cmp al, 02h
pascal@25706 417 jne I21x5
pascal@25706 418 dec bx
pascal@25706 419 mov al, dl
pascal@25706 420
pascal@25706 421 putc: mov ah, 0Eh
pascal@25706 422 inc bx
pascal@25706 423 int 10h
pascal@25706 424 dec bx
pascal@25706 425 jnz Iret1
pascal@25706 426
pascal@25706 427 putslp: lodsb
pascal@25706 428 cmp al,'$'
pascal@25706 429 jnz putc
pascal@25706 430 xchg ax, bx
pascal@25706 431
pascal@25706 432 I21x5: push ds
pascal@25706 433 mov ds, bx
pascal@25706 434 mov bl, ah
pascal@25706 435 shl bx, 2
pascal@25706 436 cmp al, 35h
pascal@25706 437 je I2135
pascal@25706 438 pop ds
pascal@25706 439 cmp al, 25h
pascal@25706 440 jne Iret1
pascal@25706 441
pascal@25706 442 I2125: les bx, [bx]
pascal@25706 443 pop ax
pascal@25706 444 jmp Iret2
pascal@25706 445
pascal@25706 446 I2135: push dx
pascal@25706 447 pop dword [bx]
pascal@25706 448 Iret1: pop bx
pascal@25706 449 Iret2: pop ax
pascal@25706 450 pop ds
pascal@25706 451 pop si
pascal@25706 452 iret
pascal@25706 453
pascal@25706 454 %endif
pascal@25706 455
pascal@25485 456 %if ExtraBootSector != 0
pascal@25486 457 %endm
pascal@25564 458 %macro BootCode 0
pascal@25485 459 %endif
pascal@24476 460
pascal@24476 461 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 462 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 463 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 464 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 465 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 466 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 467
pascal@24476 468 ReloCycle:
pascal@24476 469 add [di+2], bp ; item seg (abs)
pascal@24476 470 les si, [di] ; si = item ofs, es = item seg
pascal@24476 471 add [es:si], bp ; fixup
pascal@24525 472 scasw ; di += 2
pascal@24525 473 scasw ; point to next entry
pascal@24476 474
pascal@24476 475 RelocateEXE:
pascal@24942 476 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 477 jns ReloCycle
pascal@24942 478
pascal@24945 479 les si, [bx+0Eh]
pascal@24945 480 add si, bp
pascal@24945 481 mov ss, si ; ss for EXE
pascal@24945 482 mov sp, es ; sp for EXE
pascal@24476 483
pascal@24476 484 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 485 push si ; containing the PSP structure
pascal@24476 486
pascal@24476 487 add bp, [bx+16h] ; cs for EXE
pascal@24535 488 mov di, [bx+14h] ; ip for EXE
pascal@24476 489 Run:
pascal@24476 490 pop ds
pascal@24476 491 push bp
pascal@24535 492 push di
pascal@24476 493 push ds
pascal@24476 494 pop es
pascal@24942 495 mov [80h], ax ; clear cmdline
pascal@24942 496 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 497
pascal@24476 498 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 499 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 500 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 501 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 502 mov si, 16381 ; prime number 2**14-3
pascal@24476 503 mov di, 32749 ; prime number 2**15-19
pascal@24476 504 mov bp, 65521 ; prime number 2**16-15
pascal@24476 505
pascal@24476 506 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 507 ;; All done, transfer control to the program now ;;
pascal@24476 508 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 509 retf
pascal@25706 510
pascal@25485 511 %if ExtraBootSector != 0
pascal@25485 512 %endm
pascal@25485 513 %endif
pascal@24476 514
pascal@25458 515 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 516 ;; Error Messaging Code ;;
pascal@25458 517 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 518
pascal@25458 519 Error:
pascal@25706 520 %if Int21h
pascal@25706 521 pop dx
pascal@25706 522 %if WaitForKey != 0
pascal@25706 523 mov ax, 0900h
pascal@25706 524 %else
pascal@25706 525 mov ah, 09h
pascal@25706 526 %endif
pascal@25706 527 int 21h
pascal@25706 528 %else
pascal@25458 529 pop si
pascal@25458 530 puts:
pascal@25458 531 mov ah, 0Eh
pascal@25458 532 mov bl, 7
pascal@25458 533 lodsb
pascal@25458 534 int 10h
pascal@25458 535 cmp al, '.'
pascal@25458 536 jne puts
pascal@25706 537 %endif
pascal@25564 538 %if WaitForKey != 0
pascal@25706 539 %if Int21h == 0
pascal@25458 540 cbw
pascal@25706 541 %endif
pascal@25458 542 int 16h ; wait for a key...
pascal@25458 543 int 19h ; bootstrap
pascal@25564 544 %endif
pascal@25458 545
pascal@25458 546 Stop:
pascal@25458 547 hlt
pascal@25458 548 jmp short Stop
pascal@25458 549
pascal@25458 550 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 551 ;; Reads a FAT32 sector ;;
pascal@25458 552 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 553 ;; Inout: ES:BX -> buffer ;;
pascal@25458 554 ;; EAX = prev sector ;;
pascal@25458 555 ;; CX = rem sectors in cluster ;;
pascal@25458 556 ;; ESI = next cluster ;;
pascal@25458 557 ;; Output: EAX = current sector ;;
pascal@25458 558 ;; CX = rem sectors in cluster ;;
pascal@25458 559 ;; ESI = next cluster ;;
pascal@25458 560 ;; BP -> para / sector ;;
pascal@25458 561 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 562
pascal@25458 563 ReadClusterSector:
pascal@25458 564 %if SectorOf512Bytes != 0
pascal@25458 565 mov bp, 32 ; bp = paragraphs per sector
pascal@25458 566 %else
pascal@24525 567 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 568 shr bp, 4 ; bp = paragraphs per sector
pascal@25458 569 %endif
pascal@25564 570 inc eax ; adjust LBA for next sector
pascal@24525 571 inc cx
pascal@24525 572 loop ReadSectorLBA
pascal@24525 573
pascal@25449 574 mul ebx ; edx:eax = 0
pascal@25458 575 %if SectorOf512Bytes != 0
pascal@25458 576 mov al, 128 ; ax=# of FAT32 entries per sector
pascal@25458 577 %else
pascal@24945 578 imul ax, bp, byte 4 ; ax=# of FAT32 entries per sector
pascal@25458 579 %endif
pascal@24525 580 lea edi, [esi-2] ; esi=cluster #
pascal@24476 581 xchg eax, esi
pascal@24478 582 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 583
pascal@24525 584 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@25485 585 %if NonMirroredFATs != 0
pascal@25564 586 cdq
pascal@25485 587 or dl, byte [bx(bsExtendedFlags)]
pascal@25485 588 jns MirroredFATs ; Non-mirrored FATs ?
pascal@25485 589 and dl, 0Fh
pascal@25485 590 imul edx, dword [bx(bsSectorsPerFAT32)] ; we need to read the active one
pascal@25485 591 add eax, edx
pascal@25485 592 MirroredFATs:
pascal@25564 593 cdq
pascal@25485 594 %else
pascal@25485 595 %if LBA48bits != 0
pascal@25564 596 cdq
pascal@25485 597 %endif
pascal@25449 598 %endif
pascal@25458 599 call ReadSectorLBAfromFAT ; read 1 FAT32 sector
pascal@24476 600
pascal@25449 601 %if ClusterMask != 0
pascal@24478 602 and byte [es:si+3], 0Fh ; mask cluster value
pascal@25449 603 %endif
pascal@24478 604 mov esi, [es:si] ; esi=next cluster #
pascal@24476 605
pascal@25458 606 %if Always2FATs != 0
pascal@25458 607 imul eax, dword [bx(bsSectorsPerFAT32)], 2
pascal@25458 608 %else
pascal@24525 609 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 610 mul dword [bx(bsSectorsPerFAT32)]
pascal@25458 611 %endif
pascal@24525 612
pascal@24525 613 xchg eax, edi
pascal@25454 614 movzx ecx, byte [bx(bpbSectorsPerCluster)] ; 8..128
pascal@24945 615 mul ecx ; edx:eax=sector number in data area
pascal@24525 616 add eax, edi
pascal@24476 617
pascal@25458 618 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 619 ;; Reads a sector form the start of FAT ;;
pascal@25458 620 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 621
pascal@25458 622 ReadSectorLBAfromFAT:
pascal@25449 623 %if LBA48bits != 0
pascal@25564 624 push dx
pascal@25449 625 %endif
pascal@25454 626 mov dx, [bx(bpbReservedSectors)]
pascal@25564 627 add eax, edx
pascal@25565 628 %if LBA48bits != 0
pascal@25564 629 pop dx ; 16TB FAT32 max
pascal@25564 630 adc dx, bx
pascal@25564 631 ReadSectorBoot:
pascal@25564 632 mov [bx(HiLBA)], dx
pascal@25564 633 %endif
pascal@24476 634
pascal@24478 635 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 636 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 637 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 638 ;; Input: EAX+EDX = LBA ;;
pascal@24478 639 ;; ES:BX -> buffer address ;;
pascal@25564 640 ;; Keep: ESI = next cluster ;;
pascal@25564 641 ;; EDI = data cluster ;;
pascal@25564 642 ;; BP = paragraphs / sector ;;
pascal@25564 643 ;; CX = sector count ;;
pascal@24478 644 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 645
pascal@24476 646 ReadSectorLBA:
pascal@25449 647 %if LBA48bits != 0
pascal@25564 648 mov dx, [bx(HiLBA)]
pascal@25564 649 %else
pascal@25564 650 xor dx, dx ; 2TB FAT32 max
pascal@25564 651 ReadSectorBoot:
pascal@25449 652 %endif
pascal@25564 653 pushad
pascal@24476 654
pascal@25564 655 add eax, [bx(bpbHiddenSectors)]
pascal@25564 656 adc dx, bx ; 2TB partition offset max
pascal@25564 657
pascal@25564 658 push edx
pascal@24478 659 push eax
pascal@24476 660 push es
pascal@24476 661 push bx
pascal@24478 662 push byte 1 ; sector count word = 1
pascal@24525 663 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 664
pascal@25449 665 %if CHSsupport != 0
pascal@25449 666 ; Busybox mkdosfs creates fat32 for floppies.
pascal@25449 667 ; Floppies may support CHS only.
pascal@25564 668 %if LBA48bits != 0
pascal@25564 669 ; The following check is only useful with bpbSectorsPerTrack < 8 with disk > 4TB...
pascal@25564 670 ; setnz dl ; force cylinder overflow without divide error
pascal@25458 671 %endif
pascal@25564 672 movzx ecx, word [bx(bpbSectorsPerTrack)]
pascal@25564 673 idiv ecx
pascal@25564 674 ; eax = LBA / SPT
pascal@25564 675 ; edx = LBA % SPT = sector - 1
pascal@25449 676 inc dx
pascal@25564 677 push dx ; save sector no.
pascal@25564 678 cdq
pascal@25564 679 mov cx, word [bx(bpbHeadsPerCylinder)]
pascal@25564 680 idiv ecx
pascal@25564 681 pop cx
pascal@25564 682 ; eax = (LBA / SPT) / HPC = cylinder
pascal@25564 683 ; dl = (LBA / SPT) % HPC = head
pascal@25449 684
pascal@25458 685 xchg ch, al ; clear al
pascal@25449 686 ; ch = LSB 0...7 of cylinder no.
pascal@25564 687 %if CHSsanityCheck != 0
pascal@25564 688 shl eax, 6
pascal@25564 689 %else
pascal@25564 690 shl ax, 6
pascal@25564 691 %endif
pascal@25564 692 or cl, ah
pascal@25449 693 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@25449 694 mov dh, dl
pascal@25449 695 ; dh = head no.
pascal@25449 696 %endif
pascal@25449 697
pascal@25454 698 ReadSectorRetry:
pascal@25564 699 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24525 700 mov si, sp
pascal@24478 701 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 702 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 703 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 704
pascal@25449 705 %if CHSsupport != 0
pascal@25572 706 mov ax, 201h ; al = sector count = 1
pascal@25572 707 ; ah = 2 = read function no.
pascal@25564 708 %if CHSsanityCheck != 0
pascal@25564 709 cmp eax, 0FFFFh ; max cylinder = 1023
pascal@25564 710 ja SkipCHS
pascal@25564 711 %endif
pascal@25449 712 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@25449 713
pascal@25449 714 jnc ReadSuccess ; CF = 0 if no error
pascal@25564 715 SkipCHS:
pascal@25449 716 %endif
pascal@25449 717 %if ReadRetry != 0
pascal@25458 718 %if CHSsupport != 0
pascal@25449 719 cbw ; ah = 0 = reset function
pascal@25458 720 %else
pascal@24945 721 xor ax, ax ; ah = 0 = reset function
pascal@25458 722 %endif
pascal@24476 723 int 13h ; reset drive (DL)
pascal@24476 724
pascal@25457 725 dec bp ; up to 32 retries
pascal@25454 726 jnz ReadSectorRetry
pascal@25449 727 %endif
pascal@25706 728 Abort "Read error"
pascal@24476 729
pascal@24478 730 ReadSuccess:
pascal@24476 731
pascal@24476 732 popa ; sp += 16
pascal@25564 733 popad
pascal@25564 734 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 735 ret
pascal@24476 736
pascal@25486 737 %if ExtraBootSector != 0
pascal@25486 738 MovedCode
pascal@25564 739 BootCode
pascal@25486 740 %endif
pascal@25486 741
pascal@24942 742 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 743 ;; Fill free space with zeroes ;;
pascal@24942 744 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 745
pascal@25458 746 times (512-13-($-$$)) db 0
pascal@24476 747
pascal@24476 748 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 749 ;; Name of the file to load and run ;;
pascal@24476 750 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 751
pascal@25463 752 NameLength equ 11
pascal@25463 753 ProgramName times NameLength db 0 ; name and extension
pascal@24476 754
pascal@24476 755 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 756 ;; End of the sector ID ;;
pascal@24476 757 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 758
pascal@25564 759 dw 0AA55h ; BIOS checks for this ID
pascal@25485 760
pascal@25485 761 %if ExtraBootSector != 0
pascal@25564 762 dd 61415252h ; "RRaA"
pascal@25564 763 BootFileName
pascal@25564 764 times (996-($-$$)) db 0
pascal@25564 765 ; dd 41617272h ; "rrAa"
pascal@25485 766 %endif