wok annotate BootProg/stuff/boot32.asm @ rev 25698

Up beep (1.4.12), gsoap (2.8.134), perl-test-warnings (0.033)
author Pascal Bellard <pascal.bellard@slitaz.org>
date Sun May 26 08:12:35 2024 +0000 (15 months ago)
parents 82f370bad6b5
children 65c2646b484d
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24535 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24535 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@25460 20 ;; Its maximum size can be up to 637KB without Extended BIOS Data area. ;;
pascal@24476 21 ;; ;;
pascal@24476 22 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 23 ;; ("File not found" or "Read error") ;;
pascal@24476 24 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 25 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; ;;
pascal@25564 28 ;; Known Limitation: ;;
pascal@25564 29 ;; ~~~~~~~~~~~~~~~~~ ;;
pascal@25564 30 ;; - Need a up to date field bpbHiddenSectors to work in a partition ; ;;
pascal@25564 31 ;; most formatters don't update it correcly in extended partitions. ;;
pascal@25564 32 ;; ;;
pascal@25564 33 ;; - Requires i80386 or better CPU. ;;
pascal@25564 34 ;; ;;
pascal@25564 35 ;; ;;
pascal@24476 36 ;; Known Bugs: ;;
pascal@24476 37 ;; ~~~~~~~~~~~ ;;
pascal@24476 38 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 39 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 40 ;; ;;
pascal@24476 41 ;; ;;
pascal@24476 42 ;; Memory Layout: ;;
pascal@24476 43 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 44 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 45 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 46 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 47 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 48 ;; ;;
pascal@24476 49 ;; physical address ;;
pascal@24476 50 ;; +------------------------+ 00000H ;;
pascal@24476 51 ;; | Interrupt Vector Table | ;;
pascal@24476 52 ;; +------------------------+ 00400H ;;
pascal@24476 53 ;; | BIOS Data Area | ;;
pascal@24476 54 ;; +------------------------+ 00500H ;;
pascal@24476 55 ;; | PrtScr Status / Unused | ;;
pascal@24476 56 ;; +------------------------+ 00600H ;;
pascal@24476 57 ;; | Loaded Image | ;;
pascal@24476 58 ;; +------------------------+ nnnnnH ;;
pascal@24476 59 ;; | Available Memory | ;;
pascal@25460 60 ;; +------------------------+ A0000H - 1KB ;;
pascal@24476 61 ;; | Boot Sector | ;;
pascal@25460 62 ;; +------------------------+ A0000H - 0.5KB ;;
pascal@25460 63 ;; | 0.5KB Boot Stack | ;;
pascal@24476 64 ;; +------------------------+ A0000H ;;
pascal@24476 65 ;; | Video RAM | ;;
pascal@24476 66 ;; ;;
pascal@24476 67 ;; ;;
pascal@24476 68 ;; Boot Image Startup (register values): ;;
pascal@24476 69 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 70 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 71 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 72 ;; cs:ip = program entry point ;;
pascal@24476 73 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 74 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 75 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 76 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 77 ;; Magic numbers: ;;
pascal@24476 78 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 79 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 80 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 81 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 82 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 83 ;; metal and MS-DOS programs. ;;
pascal@24945 84 ;; The command line contains no arguments. ;;
pascal@24476 85 ;; ;;
pascal@24476 86 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 87
pascal@24491 88 %define bx(label) bx+label-boot
pascal@25449 89 %define si(label) si+label-boot
pascal@25485 90 ExtraBootSector equ 1
pascal@25449 91 ClusterMask equ 1 ; +9 bytes
pascal@25460 92 NullEntryCheck equ 1 ; +5 bytes
pascal@25572 93 CheckAttrib equ 0 ; +6 bytes
pascal@25569 94 NonMirroredFATs equ 1 ; +20 bytes
pascal@25569 95 ReadRetry equ 1 ; +6/7 bytes
pascal@25569 96 LBA48bits equ 1 ; +10 bytes
pascal@25569 97 CHSsupport equ 1 ; +35 bytes max 8GB
pascal@25569 98 CHSgeometryCheck equ 1 ; +20 bytes
pascal@25569 99 CHSsanityCheck equ 1 ; +9 bytes
pascal@25569 100 SectorOf512Bytes equ 0 ; -4 bytes
pascal@25458 101 Always2FATs equ 0 ; -4 bytes
pascal@25564 102 WaitForKey equ 0 ; +5 bytes
pascal@25698 103 AnyWhere equ 1 ; +4 bytes
pascal@24491 104
pascal@24476 105 [BITS 16]
pascal@25564 106 [CPU 386]
pascal@24476 107
pascal@24478 108 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@25460 109 StackSize equ 512
pascal@24476 110
pascal@24476 111 [SECTION .text]
pascal@24476 112 [ORG 0]
pascal@24476 113
pascal@24476 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 115 ;; Boot sector starts here ;;
pascal@24476 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 117
pascal@24491 118 boot:
pascal@25458 119 DriveNumber equ boot+0
pascal@25458 120 HiLBA equ boot+2
pascal@24476 121 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 122 nop
pascal@24476 123 bsOemName DB "BootProg" ; 0x03
pascal@24476 124
pascal@24476 125 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 126 ;; BPB1 starts here ;;
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 128
pascal@25564 129 bpbBytesPerSector DW 0 ; 0x0B 512, 1024, 2048 or 4096
pascal@25564 130 bpbSectorsPerCluster DB 0 ; 0x0D 1, 2, 4, 8, 16, 32, 64 or 128
pascal@25564 131 bpbReservedSectors DW 0 ; 0x0E 32
pascal@25564 132 bpbNumberOfFATs DB 0 ; 0x10 2
pascal@25564 133 bpbRootEntries DW 0 ; 0x11 0
pascal@25564 134 bpbTotalSectors DW 0 ; 0x13 0
pascal@25564 135 bpbMedia DB 0 ; 0x15 F8, F0
pascal@25564 136 bpbSectorsPerFAT DW 0 ; 0x16 0
pascal@24479 137 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 138 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 139 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 140 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 141
pascal@24476 142 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 143 ;; BPB1 ends here ;;
pascal@24476 144 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 145
pascal@24476 146 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 147 ;; BPB2 starts here ;;
pascal@24476 148 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 149
pascal@24479 150 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 151 bsExtendedFlags DW 0 ; 0x28
pascal@24479 152 bsFSVersion DW 0 ; 0x2A
pascal@24479 153 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 154 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 155 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 156 bsreserved times 12 DB 0 ; 0x34
pascal@24479 157 bsDriveNumber DB 0 ; 0x40
pascal@24479 158 bsreserved1 DB 0 ; 0x41
pascal@25564 159 bsExtendedBootSignature DB 0 ; 0x42 29
pascal@24479 160 bsVolumeSerialNumber DD 0 ; 0x43
pascal@25458 161 bsVolumeLabel times 11 DB " " ; 0x47 "NO NAME "
pascal@25458 162 bsFileSystemName times 8 DB " " ; 0x52 "FAT32 "
pascal@24476 163
pascal@24476 164 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 165 ;; BPB2 ends here ;;
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 167
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169 ;; Boot sector code starts here ;;
pascal@24476 170 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 171
pascal@24476 172 start:
pascal@24476 173
pascal@24476 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 175 ;; How much RAM is there? ;;
pascal@24476 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 177
pascal@24476 178 int 12h ; get conventional memory size (in KBs)
pascal@25698 179 %if AnyWhere
pascal@25698 180 call here
pascal@25698 181 here:
pascal@25698 182 pop si
pascal@25698 183 sub si, here - boot
pascal@25698 184 push cs
pascal@25698 185 pop ds
pascal@25698 186 %endif
pascal@25460 187 dec ax ; reserve 1K bytes for the code and the stack
pascal@24525 188 mov cx, 106h
pascal@24525 189 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 190
pascal@24476 191 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 192 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194
pascal@24525 195 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@25485 196 %if ExtraBootSector == 0
pascal@24525 197 mov ss, ax
pascal@24525 198 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@25485 199 %endif
pascal@24476 200
pascal@24476 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 202 ;; Copy ourselves to top of memory ;;
pascal@24476 203 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 204
pascal@25698 205 xor di, di
pascal@25698 206 %if AnyWhere == 0
pascal@24476 207 mov si, 7C00h
pascal@24476 208 mov ds, di
pascal@25698 209 %endif
pascal@25449 210 push es
pascal@25449 211 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@25698 212 cld
pascal@25698 213 rep movsw ; move 512 bytes (+ 12)
pascal@24476 214
pascal@24476 215 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 216 ;; Jump to the copy ;;
pascal@24476 217 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 218
pascal@25486 219 %if ExtraBootSector != 0
pascal@25486 220 push word main
pascal@25486 221 %else
pascal@25450 222 push byte main
pascal@25486 223 %endif
pascal@24476 224 retf
pascal@24476 225
pascal@25486 226 %if ExtraBootSector != 0
pascal@25486 227 %macro MovedCode 0
pascal@25486 228 %endif
pascal@24476 229 main:
pascal@25485 230 %if ExtraBootSector != 0
pascal@25485 231 add al, 32
pascal@25564 232 push ax
pascal@25564 233 %endif
pascal@25564 234 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 235 ;; Get drive parameters ;;
pascal@25564 236 ;; Update heads count ;;
pascal@25564 237 ;; for current BIOS ;;
pascal@25564 238 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 239
pascal@25564 240 %if CHSgeometryCheck != 0
pascal@25564 241 mov ah, 8 ; update AX,BL,CX,DX,DI, and ES registers
pascal@25564 242 int 13h ; may destroy SI,BP, and DS registers
pascal@25564 243 %endif
pascal@25564 244 push cs
pascal@25564 245 pop ds
pascal@25564 246 xor ebx, ebx
pascal@25564 247
pascal@25564 248 %if CHSgeometryCheck != 0
pascal@25564 249 and cx, byte 3Fh
pascal@25564 250 je BadParams ; verify updated and validity
pascal@25564 251 mov [bx(bpbSectorsPerTrack)], cx
pascal@25564 252 mov cl, dh
pascal@25564 253 inc cx
pascal@25564 254 mov [bx(bpbHeadsPerCylinder)], cx
pascal@25564 255 xor cx, cx
pascal@25564 256 BadParams:
pascal@25564 257 %endif
pascal@25564 258 %if ExtraBootSector != 0
pascal@25564 259 pop es
pascal@25564 260 mul ebx ; edx:eax = 0
pascal@25564 261 inc ax
pascal@25485 262 call ReadSectorBoot
pascal@25485 263 push ds
pascal@25485 264 pop ss
pascal@25485 265 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@25485 266 %endif
pascal@24476 267
pascal@25449 268 %if ClusterMask != 0
pascal@24491 269 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@25449 270 %endif
pascal@24491 271 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 272
pascal@24478 273 push byte ImageLoadSeg
pascal@24478 274 pop es
pascal@25449 275
pascal@25449 276 RootDirReadContinue:
pascal@25458 277 call ReadClusterSector ; read one sector of the root dir
pascal@24476 278
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 281 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 282
pascal@24476 283 xor di, di ; es:di -> root entries array
pascal@24476 284
pascal@24476 285 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 286 ;; Looks for a file/dir by its name ;;
pascal@24476 287 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 288 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 289 ;; ES:DI -> root directory array ;;
pascal@24525 290 ;; BP = paragraphs in sector ;;
pascal@24476 291 ;; Output: ESI = cluster number ;;
pascal@24476 292 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 293
pascal@24476 294 FindNameCycle:
pascal@25449 295 %if NullEntryCheck != 0
pascal@24525 296 cmp byte [es:di], bh
pascal@24478 297 je ErrFind ; end of root directory (NULL entry found)
pascal@25449 298 %endif
pascal@24478 299 pusha
pascal@25454 300 mov cl, NameLength
pascal@24525 301 mov si, ProgramName ; ds:si -> program name
pascal@24476 302 repe cmpsb
pascal@25467 303 VolumeLabel equ 8
pascal@25467 304 SubDirectory equ 10h
pascal@25564 305 %if CheckAttrib != 0
pascal@25467 306 jnz SkipFindName
pascal@25467 307 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 308 SkipFindName:
pascal@25467 309 %endif
pascal@24525 310 je FindNameFound
pascal@24478 311 popa
pascal@24525 312 add di, byte 32
pascal@24476 313 dec bp
pascal@24476 314 dec bp
pascal@24476 315 jnz FindNameCycle ; next root entry
pascal@25458 316 loop RootDirReadContinue ; next sector in cluster
pascal@25458 317 cmp esi, 0FFFFFF6h ; carry=0 if last cluster, and carry=1 otherwise
pascal@25458 318 jnc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 319 ErrFind:
pascal@24478 320 call Error ; end of root directory (dir end reached)
pascal@24476 321 db "File not found."
pascal@25564 322 %if ExtraBootSector != 0
pascal@25564 323 %endm
pascal@25564 324 %macro BootFileName 0
pascal@25564 325 %endif
pascal@24476 326 FindNameFound:
pascal@24525 327 push word [es:di+14h-11]
pascal@24525 328 push word [es:di+1Ah-11]
pascal@24478 329 pop esi ; esi = cluster no. cx = 0
pascal@24476 330
pascal@24525 331 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 332 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 333
pascal@24476 334 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 335 ;; Load the entire file ;;
pascal@24476 336 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 337
pascal@24476 338 push es
pascal@24476 339 FileReadContinue:
pascal@24476 340 push di
pascal@25458 341 call ReadClusterSector ; read one sector of the boot file
pascal@25458 342 dec cx
pascal@24476 343 mov di, es
pascal@24478 344 add di, bp
pascal@24478 345 mov es, di ; es:bx updated
pascal@24476 346 pop di
pascal@24478 347
pascal@24476 348 sub di, bp
pascal@24476 349 jae FileReadContinue
pascal@24943 350 xor ax, ax
pascal@24476 351 pop bp
pascal@24476 352
pascal@24476 353 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 354 ;; Type detection, .COM or .EXE? ;;
pascal@24476 355 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 356
pascal@24476 357 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24535 358
pascal@24476 359 add bp, [bx+08h] ; bp = image base
pascal@24476 360 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 361
pascal@24476 362 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 363 je RelocateEXE ; yes, it's an EXE program
pascal@24476 364
pascal@24476 365 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 366 ;; Setup and run a .COM program ;;
pascal@24535 367 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 368 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 369 ;; cmdline=void ;;
pascal@24476 370 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 371
pascal@24535 372 mov di, 100h ; ip
pascal@24476 373 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 374 mov ss, bp
pascal@24476 375 xor sp, sp
pascal@24476 376 push bp ; cs, ds and es
pascal@25486 377 jmp short Run
pascal@25485 378 %if ExtraBootSector != 0
pascal@25486 379 %endm
pascal@25564 380 %macro BootCode 0
pascal@25485 381 %endif
pascal@24476 382
pascal@24476 383 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 384 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 385 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 386 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 387 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 389
pascal@24476 390 ReloCycle:
pascal@24476 391 add [di+2], bp ; item seg (abs)
pascal@24476 392 les si, [di] ; si = item ofs, es = item seg
pascal@24476 393 add [es:si], bp ; fixup
pascal@24525 394 scasw ; di += 2
pascal@24525 395 scasw ; point to next entry
pascal@24476 396
pascal@24476 397 RelocateEXE:
pascal@24942 398 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 399 jns ReloCycle
pascal@24942 400
pascal@24945 401 les si, [bx+0Eh]
pascal@24945 402 add si, bp
pascal@24945 403 mov ss, si ; ss for EXE
pascal@24945 404 mov sp, es ; sp for EXE
pascal@24476 405
pascal@24476 406 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 407 push si ; containing the PSP structure
pascal@24476 408
pascal@24476 409 add bp, [bx+16h] ; cs for EXE
pascal@24535 410 mov di, [bx+14h] ; ip for EXE
pascal@24476 411 Run:
pascal@24476 412 pop ds
pascal@24476 413 push bp
pascal@24535 414 push di
pascal@24476 415 push ds
pascal@24476 416 pop es
pascal@24942 417 mov [80h], ax ; clear cmdline
pascal@24942 418 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 419
pascal@24476 420 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 421 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 422 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 423 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 424 mov si, 16381 ; prime number 2**14-3
pascal@24476 425 mov di, 32749 ; prime number 2**15-19
pascal@24476 426 mov bp, 65521 ; prime number 2**16-15
pascal@24476 427
pascal@24476 428 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 429 ;; All done, transfer control to the program now ;;
pascal@24476 430 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 431 retf
pascal@25485 432 %if ExtraBootSector != 0
pascal@25485 433 %endm
pascal@25485 434 %endif
pascal@24476 435
pascal@25458 436 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 437 ;; Error Messaging Code ;;
pascal@25458 438 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 439
pascal@25458 440 Error:
pascal@25458 441 pop si
pascal@25458 442 puts:
pascal@25458 443 mov ah, 0Eh
pascal@25458 444 mov bl, 7
pascal@25458 445 lodsb
pascal@25458 446 int 10h
pascal@25458 447 cmp al, '.'
pascal@25458 448 jne puts
pascal@25564 449 %if WaitForKey != 0
pascal@25458 450 cbw
pascal@25458 451 int 16h ; wait for a key...
pascal@25458 452 int 19h ; bootstrap
pascal@25564 453 %endif
pascal@25458 454
pascal@25458 455 Stop:
pascal@25458 456 hlt
pascal@25458 457 jmp short Stop
pascal@25458 458
pascal@25458 459 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 460 ;; Reads a FAT32 sector ;;
pascal@25458 461 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 462 ;; Inout: ES:BX -> buffer ;;
pascal@25458 463 ;; EAX = prev sector ;;
pascal@25458 464 ;; CX = rem sectors in cluster ;;
pascal@25458 465 ;; ESI = next cluster ;;
pascal@25458 466 ;; Output: EAX = current sector ;;
pascal@25458 467 ;; CX = rem sectors in cluster ;;
pascal@25458 468 ;; ESI = next cluster ;;
pascal@25458 469 ;; BP -> para / sector ;;
pascal@25458 470 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 471
pascal@25458 472 ReadClusterSector:
pascal@25458 473 %if SectorOf512Bytes != 0
pascal@25458 474 mov bp, 32 ; bp = paragraphs per sector
pascal@25458 475 %else
pascal@24525 476 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 477 shr bp, 4 ; bp = paragraphs per sector
pascal@25458 478 %endif
pascal@25564 479 inc eax ; adjust LBA for next sector
pascal@24525 480 inc cx
pascal@24525 481 loop ReadSectorLBA
pascal@24525 482
pascal@25449 483 mul ebx ; edx:eax = 0
pascal@25458 484 %if SectorOf512Bytes != 0
pascal@25458 485 mov al, 128 ; ax=# of FAT32 entries per sector
pascal@25458 486 %else
pascal@24945 487 imul ax, bp, byte 4 ; ax=# of FAT32 entries per sector
pascal@25458 488 %endif
pascal@24525 489 lea edi, [esi-2] ; esi=cluster #
pascal@24476 490 xchg eax, esi
pascal@24478 491 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 492
pascal@24525 493 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@25485 494 %if NonMirroredFATs != 0
pascal@25564 495 cdq
pascal@25485 496 or dl, byte [bx(bsExtendedFlags)]
pascal@25485 497 jns MirroredFATs ; Non-mirrored FATs ?
pascal@25485 498 and dl, 0Fh
pascal@25485 499 imul edx, dword [bx(bsSectorsPerFAT32)] ; we need to read the active one
pascal@25485 500 add eax, edx
pascal@25485 501 MirroredFATs:
pascal@25564 502 cdq
pascal@25485 503 %else
pascal@25485 504 %if LBA48bits != 0
pascal@25564 505 cdq
pascal@25485 506 %endif
pascal@25449 507 %endif
pascal@25458 508 call ReadSectorLBAfromFAT ; read 1 FAT32 sector
pascal@24476 509
pascal@25449 510 %if ClusterMask != 0
pascal@24478 511 and byte [es:si+3], 0Fh ; mask cluster value
pascal@25449 512 %endif
pascal@24478 513 mov esi, [es:si] ; esi=next cluster #
pascal@24476 514
pascal@25458 515 %if Always2FATs != 0
pascal@25458 516 imul eax, dword [bx(bsSectorsPerFAT32)], 2
pascal@25458 517 %else
pascal@24525 518 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 519 mul dword [bx(bsSectorsPerFAT32)]
pascal@25458 520 %endif
pascal@24525 521
pascal@24525 522 xchg eax, edi
pascal@25454 523 movzx ecx, byte [bx(bpbSectorsPerCluster)] ; 8..128
pascal@24945 524 mul ecx ; edx:eax=sector number in data area
pascal@24525 525 add eax, edi
pascal@24476 526
pascal@25458 527 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 528 ;; Reads a sector form the start of FAT ;;
pascal@25458 529 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 530
pascal@25458 531 ReadSectorLBAfromFAT:
pascal@25449 532 %if LBA48bits != 0
pascal@25564 533 push dx
pascal@25449 534 %endif
pascal@25454 535 mov dx, [bx(bpbReservedSectors)]
pascal@25564 536 add eax, edx
pascal@25565 537 %if LBA48bits != 0
pascal@25564 538 pop dx ; 16TB FAT32 max
pascal@25564 539 adc dx, bx
pascal@25564 540 ReadSectorBoot:
pascal@25564 541 mov [bx(HiLBA)], dx
pascal@25564 542 %endif
pascal@24476 543
pascal@24478 544 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 545 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 546 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 547 ;; Input: EAX+EDX = LBA ;;
pascal@24478 548 ;; ES:BX -> buffer address ;;
pascal@25564 549 ;; Keep: ESI = next cluster ;;
pascal@25564 550 ;; EDI = data cluster ;;
pascal@25564 551 ;; BP = paragraphs / sector ;;
pascal@25564 552 ;; CX = sector count ;;
pascal@24478 553 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 554
pascal@24476 555 ReadSectorLBA:
pascal@25449 556 %if LBA48bits != 0
pascal@25564 557 mov dx, [bx(HiLBA)]
pascal@25564 558 %else
pascal@25564 559 xor dx, dx ; 2TB FAT32 max
pascal@25564 560 ReadSectorBoot:
pascal@25449 561 %endif
pascal@25564 562 pushad
pascal@24476 563
pascal@25564 564 add eax, [bx(bpbHiddenSectors)]
pascal@25564 565 adc dx, bx ; 2TB partition offset max
pascal@25564 566
pascal@25564 567 push edx
pascal@24478 568 push eax
pascal@24476 569 push es
pascal@24476 570 push bx
pascal@24478 571 push byte 1 ; sector count word = 1
pascal@24525 572 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 573
pascal@25449 574 %if CHSsupport != 0
pascal@25449 575 ; Busybox mkdosfs creates fat32 for floppies.
pascal@25449 576 ; Floppies may support CHS only.
pascal@25564 577 %if LBA48bits != 0
pascal@25564 578 ; The following check is only useful with bpbSectorsPerTrack < 8 with disk > 4TB...
pascal@25564 579 ; setnz dl ; force cylinder overflow without divide error
pascal@25458 580 %endif
pascal@25564 581 movzx ecx, word [bx(bpbSectorsPerTrack)]
pascal@25564 582 idiv ecx
pascal@25564 583 ; eax = LBA / SPT
pascal@25564 584 ; edx = LBA % SPT = sector - 1
pascal@25449 585 inc dx
pascal@25564 586 push dx ; save sector no.
pascal@25564 587 cdq
pascal@25564 588 mov cx, word [bx(bpbHeadsPerCylinder)]
pascal@25564 589 idiv ecx
pascal@25564 590 pop cx
pascal@25564 591 ; eax = (LBA / SPT) / HPC = cylinder
pascal@25564 592 ; dl = (LBA / SPT) % HPC = head
pascal@25449 593
pascal@25458 594 xchg ch, al ; clear al
pascal@25449 595 ; ch = LSB 0...7 of cylinder no.
pascal@25564 596 %if CHSsanityCheck != 0
pascal@25564 597 shl eax, 6
pascal@25564 598 %else
pascal@25564 599 shl ax, 6
pascal@25564 600 %endif
pascal@25564 601 or cl, ah
pascal@25449 602 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@25449 603 mov dh, dl
pascal@25449 604 ; dh = head no.
pascal@25449 605 %endif
pascal@25449 606
pascal@25454 607 ReadSectorRetry:
pascal@25564 608 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24525 609 mov si, sp
pascal@24478 610 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 611 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 612 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 613
pascal@25449 614 %if CHSsupport != 0
pascal@25572 615 mov ax, 201h ; al = sector count = 1
pascal@25572 616 ; ah = 2 = read function no.
pascal@25564 617 %if CHSsanityCheck != 0
pascal@25564 618 cmp eax, 0FFFFh ; max cylinder = 1023
pascal@25564 619 ja SkipCHS
pascal@25564 620 %endif
pascal@25449 621 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@25449 622
pascal@25449 623 jnc ReadSuccess ; CF = 0 if no error
pascal@25564 624 SkipCHS:
pascal@25449 625 %endif
pascal@25449 626 %if ReadRetry != 0
pascal@25458 627 %if CHSsupport != 0
pascal@25449 628 cbw ; ah = 0 = reset function
pascal@25458 629 %else
pascal@24945 630 xor ax, ax ; ah = 0 = reset function
pascal@25458 631 %endif
pascal@24476 632 int 13h ; reset drive (DL)
pascal@24476 633
pascal@25457 634 dec bp ; up to 32 retries
pascal@25454 635 jnz ReadSectorRetry
pascal@25449 636 %endif
pascal@24525 637
pascal@24476 638 call Error
pascal@24476 639 db "Read error."
pascal@24476 640
pascal@24478 641 ReadSuccess:
pascal@24476 642
pascal@24476 643 popa ; sp += 16
pascal@25564 644 popad
pascal@25564 645 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 646 ret
pascal@24476 647
pascal@25486 648 %if ExtraBootSector != 0
pascal@25486 649 MovedCode
pascal@25564 650 BootCode
pascal@25486 651 %endif
pascal@25486 652
pascal@24942 653 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 654 ;; Fill free space with zeroes ;;
pascal@24942 655 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 656
pascal@25458 657 times (512-13-($-$$)) db 0
pascal@24476 658
pascal@24476 659 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 660 ;; Name of the file to load and run ;;
pascal@24476 661 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 662
pascal@25463 663 NameLength equ 11
pascal@25463 664 ProgramName times NameLength db 0 ; name and extension
pascal@24476 665
pascal@24476 666 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 667 ;; End of the sector ID ;;
pascal@24476 668 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 669
pascal@25564 670 dw 0AA55h ; BIOS checks for this ID
pascal@25485 671
pascal@25485 672 %if ExtraBootSector != 0
pascal@25564 673 dd 61415252h ; "RRaA"
pascal@25564 674 BootFileName
pascal@25564 675 times (996-($-$$)) db 0
pascal@25564 676 ; dd 41617272h ; "rrAa"
pascal@25485 677 %endif