wok annotate BootProg/stuff/boot16.asm @ rev 25550

Add apachetop & mysqlsniffer
author Pascal Bellard <pascal.bellard@slitaz.org>
date Mon Apr 03 16:35:42 2023 +0000 (2023-04-03)
parents 4c101652eb90
children 3c71bb4367c3
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - FAT12 and FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; - cpu 8086 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@24476 29 ;; Known Bugs: ;;
pascal@24476 30 ;; ~~~~~~~~~~~ ;;
pascal@24476 31 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 32 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 33 ;; - 360KB 5"25 ;;
pascal@24476 34 ;; - 1.2MB 5"25 ;;
pascal@24476 35 ;; - 1.44MB 3"5 ;;
pascal@24476 36 ;; on my HDD (FAT16). ;;
pascal@24476 37 ;; ;;
pascal@24476 38 ;; ;;
pascal@24476 39 ;; Memory Layout: ;;
pascal@24476 40 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 41 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 42 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 43 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 44 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; physical address ;;
pascal@24476 47 ;; +------------------------+ 00000H ;;
pascal@24476 48 ;; | Interrupt Vector Table | ;;
pascal@24476 49 ;; +------------------------+ 00400H ;;
pascal@24476 50 ;; | BIOS Data Area | ;;
pascal@24476 51 ;; +------------------------+ 00500H ;;
pascal@24476 52 ;; | PrtScr Status / Unused | ;;
pascal@24476 53 ;; +------------------------+ 00600H ;;
pascal@24476 54 ;; | Loaded Image | ;;
pascal@24476 55 ;; +------------------------+ nnnnnH ;;
pascal@24476 56 ;; | Available Memory | ;;
pascal@24476 57 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 58 ;; | Boot Sector | ;;
pascal@24476 59 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 60 ;; | 3KB Boot Stack | ;;
pascal@24476 61 ;; +------------------------+ A0000H ;;
pascal@24476 62 ;; | Video RAM | ;;
pascal@24476 63 ;; ;;
pascal@24476 64 ;; ;;
pascal@24476 65 ;; Boot Image Startup (register values): ;;
pascal@24476 66 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 67 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 68 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 69 ;; cs:ip = program entry point ;;
pascal@24476 70 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 71 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 72 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 73 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 74 ;; Magic numbers: ;;
pascal@24476 75 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 76 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 77 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 78 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 79 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 80 ;; metal and MS-DOS programs. ;;
pascal@24945 81 ;; The command line contains no arguments. ;;
pascal@24476 82 ;; ;;
pascal@24476 83 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 84
pascal@24476 85 %define bx(label) bx+label-boot
pascal@25450 86 %define si(label) si+label-boot
pascal@25458 87 NullEntryCheck equ 1 ; +2 bytes
pascal@25450 88 ReadRetry equ 1 ; +9 bytes
pascal@25450 89 LBAsupport equ 1 ; +16 bytes
pascal@25450 90 Over2GB equ 1 ; +5 bytes
pascal@25450 91 GeometryCheck equ 1 ; +18 bytes
pascal@25550 92 SectorOf512Bytes equ 0 ; -4/-6 bytes
pascal@25467 93 CheckAttrib equ 0 ; +6 bytes
pascal@24476 94
pascal@24476 95 [BITS 16]
pascal@24476 96 [CPU 8086]
pascal@24476 97
pascal@24476 98 ImageLoadSeg equ 60h
pascal@24476 99 StackSize equ 3072 ; Stack + cluster list
pascal@24476 100
pascal@24476 101 [SECTION .text]
pascal@24476 102 [ORG 0]
pascal@24476 103
pascal@24476 104 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 105 ;; Boot sector starts here ;;
pascal@24476 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 107
pascal@24476 108 boot:
pascal@25450 109 DriveNumber:
pascal@24476 110 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 111 nop
pascal@24476 112 bsOemName DB "BootProg" ; 0x03
pascal@24476 113
pascal@24476 114 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 115 ;; BPB starts here ;;
pascal@24476 116 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 117
pascal@24479 118 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 119 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 120 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 121 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 122 bpbRootEntries DW 0 ; 0x11
pascal@24479 123 bpbTotalSectors DW 0 ; 0x13
pascal@24479 124 bpbMedia DB 0 ; 0x15
pascal@24479 125 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 126 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 127 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 128 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 129 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 130
pascal@24476 131 ;;;;;;;;;;;;;;;;;;;
pascal@24476 132 ;; BPB ends here ;;
pascal@24476 133 ;;;;;;;;;;;;;;;;;;;
pascal@24476 134
pascal@24479 135 bsDriveNumber DB 0 ; 0x24
pascal@24479 136 bsUnused DB 0 ; 0x25
pascal@24479 137 bsExtBootSignature DB 0 ; 0x26
pascal@24479 138 bsSerialNumber DD 0 ; 0x27
pascal@25458 139 bsVolumeLabel times 11 DB " " ; 0x2B "NO NAME "
pascal@25458 140 bsFileSystem times 8 DB " " ; 0x36 "FAT12 " or "FAT16 "
pascal@24476 141
pascal@24476 142 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 143 ;; Boot sector code starts here ;;
pascal@24476 144 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 145
pascal@24476 146 start:
pascal@24476 147 cld
pascal@24476 148
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150 ;; How much RAM is there? ;;
pascal@24476 151 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 152
pascal@24476 153 int 12h ; get conventional memory size (in KBs)
pascal@24476 154 mov cx, 106h
pascal@24476 155 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 156
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 159 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 160
pascal@24476 161 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 162 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 163 mov ss, ax
pascal@24476 164 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 165
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167 ;; Copy ourselves to top of memory ;;
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169
pascal@24476 170 mov si, 7C00h
pascal@24476 171 xor di, di
pascal@24476 172 mov ds, di
pascal@25450 173 push es
pascal@25450 174 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 175 rep movsw ; move 512 bytes (+ 12)
pascal@24476 176
pascal@24476 177 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 178 ;; Jump to the copy ;;
pascal@24476 179 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 180
pascal@24476 181 mov cl, byte main
pascal@24476 182 push cx
pascal@24476 183 retf
pascal@24476 184
pascal@24476 185 main:
pascal@24476 186 %if ImageLoadSeg != main-boot
pascal@24476 187 %if ImageLoadSeg >= 100h
pascal@24476 188 mov cx, ImageLoadSeg
pascal@24476 189 %else
pascal@24476 190 mov cl, ImageLoadSeg
pascal@24476 191 %endif
pascal@24476 192 %endif
pascal@24476 193 push cx
pascal@24476 194
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196 ;; Get drive parameters ;;
pascal@24476 197 ;; Update heads count ;;
pascal@24476 198 ;; for current BIOS ;;
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200
pascal@25450 201 %if GeometryCheck != 0
pascal@24476 202 mov ah, 8
pascal@24476 203 int 13h ; may destroy SI,BP, and DS registers
pascal@25450 204 %endif
pascal@24476 205 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 206 push cs
pascal@24476 207 pop ds
pascal@24476 208 xor bx, bx
pascal@24476 209
pascal@25450 210 %if GeometryCheck != 0
pascal@24479 211 and cx, byte 3Fh
pascal@24476 212 cmp [bx(bpbSectorsPerTrack)], cx
pascal@24476 213 jne BadParams ; verify updated and validity
pascal@24476 214 mov al, dh
pascal@24476 215 inc ax
pascal@24476 216 mov [bpbHeadsPerCylinder], ax
pascal@24476 217 BadParams:
pascal@25450 218 %endif
pascal@24476 219
pascal@24476 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 221 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 223
pascal@24476 224 pop es ; ImageLoadSeg
pascal@24476 225 push es
pascal@24476 226
pascal@24476 227 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@25458 228 mov di, word [bx(bpbSectorsPerFAT)]
pascal@24476 229
pascal@25458 230 call ReadDISectors ; read fat; clear ax, cx, di; bp = SectorsPerFAT
pascal@24476 231
pascal@24476 232 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 233 ;; load the root directory in ;;
pascal@24476 234 ;; its entirety (16KB max) ;;
pascal@24476 235 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 236
pascal@25458 237 %if SectorOf512Bytes != 0
pascal@25458 238 mov di, word [bx(bpbRootEntries)]
pascal@25458 239 mov cl, 4
pascal@25458 240 shr di, cl ; di = root directory size in sectors
pascal@25458 241 %else
pascal@24942 242 mov al, 32
pascal@24476 243
pascal@24476 244 mul word [bx(bpbRootEntries)]
pascal@24476 245 div word [bx(bpbBytesPerSector)]
pascal@25458 246 xchg ax, di ; di = root directory size in sectors, clear ah
pascal@25458 247 %endif
pascal@24476 248
pascal@24476 249 mov al, [bpbNumberOfFATs]
pascal@25458 250 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadDISectors
pascal@24476 251
pascal@25457 252 push es ; read root directory
pascal@25458 253 call ReadDISectors ; clear ax, cx, di; bp = first data sector
pascal@24476 254 pop es
pascal@24476 255
pascal@24476 256 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 257 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 258 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 259
pascal@24476 260 ; es:di -> root entries array
pascal@24476 261
pascal@24476 262 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 263 ;; Looks for the file/dir ProgramName ;;
pascal@24476 264 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 265 ;; Input: ES:DI -> root directory array ;;
pascal@24476 266 ;; Output: SI = cluster number ;;
pascal@24476 267 ;; AX = file sector count ;;
pascal@24476 268 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 269
pascal@24476 270 FindNameCycle:
pascal@24476 271 push di
pascal@25454 272 mov cl, NameLength
pascal@24476 273 mov si, ProgramName ; ds:si -> program name
pascal@24476 274 repe cmpsb
pascal@25467 275 %if CheckAttrib != 0
pascal@25467 276 VolumeLabel equ 8
pascal@25467 277 SubDirectory equ 10h
pascal@25467 278 jnz SkipFindName
pascal@25467 279 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 280 SkipFindName:
pascal@25467 281 %endif
pascal@24476 282 pop di
pascal@24476 283 je FindNameFound
pascal@25450 284 %if NullEntryCheck != 0
pascal@25458 285 scasb ; Z == NC
pascal@25458 286 cmc
pascal@25458 287 lea di, [di+31]
pascal@25458 288 dec word [bx(bpbRootEntries)]
pascal@25458 289 ja FindNameCycle ; next root entry
pascal@25450 290 %else
pascal@25450 291 add di, byte 32
pascal@24476 292 dec word [bx(bpbRootEntries)]
pascal@24476 293 jnz FindNameCycle ; next root entry
pascal@25458 294 %endif
pascal@24476 295
pascal@24476 296 FindNameFailed:
pascal@24476 297 call Error
pascal@24476 298 db "File not found."
pascal@24476 299
pascal@24476 300 FindNameFound:
pascal@24476 301 push si
pascal@24476 302 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 303 les ax, [es:di+1Ch] ; file size
pascal@24476 304 mov dx, es
pascal@24476 305 div word [bx(bpbBytesPerSector)]
pascal@24476 306 cmp bx, dx ; sector aligned ?
pascal@24476 307 adc ax, bx ; file last sector
pascal@24476 308 pop di ; di = ClusterList
pascal@24476 309
pascal@24476 310 pop es ; ImageLoadSeg
pascal@24476 311 push ax
pascal@24476 312
pascal@24476 313 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 314 ;; build cluster list ;;
pascal@24476 315 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 316 ;; Input: ES:0 -> FAT ;;
pascal@24476 317 ;; SI = first cluster ;;
pascal@24476 318 ;; DI = cluster list :;
pascal@24476 319 ;; CH = 0 ;;
pascal@24476 320 ;; Output: SI = cluster list ;;
pascal@24476 321 ;; CH = 0 ;;
pascal@24476 322 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 323
pascal@25458 324 FAT12 equ 1
pascal@25458 325 FAT16 equ 1
pascal@25550 326 TINYFAT16 equ 1 ; < 4072 clusters fat16 support
pascal@25453 327 push di ; up to 2 * 635K / BytesPerCluster = 2540 bytes
pascal@25450 328 %if FAT12 == 1
pascal@25454 329 mov cl, 12
pascal@25450 330 %endif
pascal@24476 331 ClusterLoop:
pascal@24476 332 mov [di], si
pascal@25450 333 add si, si ; si = cluster * 2
pascal@25450 334 %if FAT16 == 1
pascal@24476 335 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@25094 336 jnc First64k
pascal@24476 337 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@25094 338 First64k:
pascal@25453 339 %if FAT12 == 1
pascal@25457 340 mov dx, 0FFF6h
pascal@25454 341 %if TINYFAT16 == 1
pascal@25550 342 test [bx(bsFileSystem+4)], cl ; FAT12 or FAT16 ? clear C (bit 2)
pascal@25458 343 jne ReadClusterFat16
pascal@25454 344 %else
pascal@25454 345 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@25458 346 ja ReadClusterFat16
pascal@25454 347 %endif
pascal@24942 348 mov dh, 0Fh
pascal@25453 349 %endif
pascal@25450 350 %endif
pascal@25450 351 %if FAT12 == 1
pascal@25087 352 add si, [di]
pascal@24476 353 shr si, 1 ; si = cluster * 3 / 2
pascal@25450 354 %endif
pascal@25450 355 %if FAT16 == 1
pascal@24942 356 ReadClusterFat16:
pascal@25094 357 push ds
pascal@25087 358 mov ds, ax
pascal@24476 359 lodsw ; ax = next cluster
pascal@25094 360 pop ds
pascal@25450 361 %else
pascal@25453 362 es lodsw
pascal@25450 363 %endif
pascal@25450 364 %if FAT12 == 1
pascal@24476 365 jnc ReadClusterEven
pascal@25454 366 rol ax, cl
pascal@24476 367 ReadClusterEven:
pascal@25094 368 scasw ; di += 2
pascal@25454 369 %if FAT16 == 1
pascal@24942 370 and ah, dh ; mask cluster value
pascal@24942 371 cmp ax, dx
pascal@25454 372 %else
pascal@25453 373 and ah, 0Fh ; mask cluster value
pascal@25457 374 cmp ax, 0FF6h
pascal@25454 375 %endif
pascal@25454 376 %else
pascal@25454 377 scasw ; di += 2
pascal@25457 378 cmp ax, 0FFF6h
pascal@25453 379 %endif
pascal@24476 380 xchg ax, si
pascal@24476 381 jc ClusterLoop
pascal@24476 382 pop si
pascal@24476 383 pop di ; file size in sectors
pascal@24476 384
pascal@24476 385 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 386 ;; Load the entire file ;;
pascal@24476 387 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 388 ;; Input: ES:0 -> buffer ;;
pascal@24476 389 ;; SI = cluster list ;;
pascal@24476 390 ;; DI = file sectors ;;
pascal@24476 391 ;; CH = 0 ;;
pascal@24945 392 ;; BP = 1st data sec ;;
pascal@24476 393 ;; Output: BP:0 -> buffer ;;
pascal@24476 394 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 395
pascal@24476 396 push es
pascal@24476 397
pascal@24476 398 ReadClusters:
pascal@24476 399 lodsw
pascal@24476 400 dec ax
pascal@24476 401 dec ax
pascal@24476 402
pascal@25454 403 mov cl, [bx(bpbSectorsPerCluster)] ; 1..128
pascal@24476 404 mul cx ; cx = sector count (ch = 0)
pascal@24476 405
pascal@24476 406 add ax, bp ; LBA for cluster data
pascal@24476 407 adc dx, bx ; dx:ax = LBA
pascal@24476 408
pascal@25458 409 call ReadSectors ; clear ax, restore dx
pascal@24476 410
pascal@25458 411 jne ReadClusters ; until end of file
pascal@24476 412
pascal@24476 413 pop bp ; ImageLoadSeg
pascal@24476 414
pascal@24476 415 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 416 ;; Type detection, .COM or .EXE? ;;
pascal@24476 417 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 418
pascal@24476 419 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 420
pascal@24476 421 add bp, [bx+08h] ; bp = image base
pascal@24476 422 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 423
pascal@24476 424 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 425 je RelocateEXE ; yes, it's an EXE program
pascal@24476 426
pascal@24476 427 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 428 ;; Setup and run a .COM program ;;
pascal@24476 429 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 430 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 431 ;; cmdline=void ;;
pascal@24476 432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 433
pascal@24942 434 mov di, 100h ; ip
pascal@24476 435 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 436 mov ss, bp
pascal@24476 437 xor sp, sp
pascal@24476 438 push bp ; cs, ds and es
pascal@24476 439 jmp short Run
pascal@24476 440
pascal@24476 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 442 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 443 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 444 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 445 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 446 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 447
pascal@24476 448 ReloCycle:
pascal@24476 449 add [di+2], bp ; item seg (abs)
pascal@24476 450 les si, [di] ; si = item ofs, es = item seg
pascal@24476 451 add [es:si], bp ; fixup
pascal@24476 452 scasw ; di += 2
pascal@24476 453 scasw ; point to next entry
pascal@24476 454
pascal@24476 455 RelocateEXE:
pascal@24942 456 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 457 jns ReloCycle
pascal@24476 458 ; PSP don't have a valid drive identifier
pascal@24476 459 les si, [bx+0Eh]
pascal@24476 460 add si, bp
pascal@24476 461 mov ss, si ; ss for EXE
pascal@24476 462 mov sp, es ; sp for EXE
pascal@24476 463
pascal@24476 464 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 465 push si ; containing the PSP structure
pascal@24476 466
pascal@24476 467 add bp, [bx+16h] ; cs for EXE
pascal@24942 468 mov di, [bx+14h] ; ip for EXE
pascal@24476 469 Run:
pascal@24476 470 pop ds
pascal@24476 471 push bp
pascal@24942 472 push di
pascal@24476 473 push ds
pascal@24476 474 pop es
pascal@24942 475 mov [80h], ax ; clear cmdline
pascal@24942 476 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 477
pascal@24476 478 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 479 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 480 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 481 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 482 mov si, 16381 ; prime number 2**14-3
pascal@24476 483 mov di, 32749 ; prime number 2**15-19
pascal@24476 484 mov bp, 65521 ; prime number 2**16-15
pascal@24476 485
pascal@24476 486 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 487 ;; All done, transfer control to the program now ;;
pascal@24476 488 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 489 retf
pascal@24476 490
pascal@25458 491 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 492 ;; Error Messaging Code ;;
pascal@25458 493 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 494
pascal@25458 495 Error:
pascal@25458 496 pop si
pascal@25458 497
pascal@25458 498 PutStr:
pascal@25458 499 mov ah, 0Eh
pascal@25458 500 mov bl, 7
pascal@25458 501 lodsb
pascal@25458 502 int 10h
pascal@25458 503 cmp al, "."
pascal@25458 504 jne PutStr
pascal@25458 505
pascal@25458 506 cbw
pascal@25458 507 int 16h ; wait for a key...
pascal@25458 508 int 19h ; bootstrap
pascal@25458 509
pascal@25458 510 Stop:
pascal@25458 511 hlt
pascal@25458 512 jmp short Stop
pascal@25458 513
pascal@25458 514 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 515 ;; Read sectors using BIOS Int 13h ;;
pascal@25458 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 517 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@25458 518 ;; BX = 0 ;;
pascal@25458 519 ;; DI = sector count ;;
pascal@25458 520 ;; ES:BX -> buffer address ;;
pascal@25458 521 ;; Output: ES:BX -> next address ;;
pascal@25458 522 ;; BX = 0 ;;
pascal@25458 523 ;; CX = 0 ;;
pascal@25458 524 ;; DI = 0 ;;
pascal@25458 525 ;; DL = drive number ;;
pascal@25458 526 ;; DX:BP = next LBA from FAT ;;
pascal@25458 527 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 528
pascal@25458 529 ReadDISectors:
pascal@25458 530 mov bp, di
pascal@24476 531 add bp, ax ; adjust LBA for cluster data
pascal@24476 532
pascal@25458 533 mov cx, di ; no cluster size limit
pascal@24476 534
pascal@24476 535 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 536 ;; Read sectors using BIOS Int 13h ;;
pascal@24476 537 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 538 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 539 ;; BX = 0 ;;
pascal@24476 540 ;; CX = sector count ;;
pascal@24476 541 ;; DI = file sectors ;;
pascal@24476 542 ;; ES:BX -> buffer address ;;
pascal@24476 543 ;; Output: ES:BX -> next address ;;
pascal@24476 544 ;; BX = 0 ;;
pascal@24476 545 ;; CX or DI = 0 ;;
pascal@24476 546 ;; DL = drive number ;;
pascal@24476 547 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 548
pascal@25458 549 ReadSectors:
pascal@24476 550 add ax, [bx(bpbHiddenSectors)]
pascal@24476 551 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 552 add ax, [bx(bpbReservedSectors)]
pascal@24476 553
pascal@24476 554 push si
pascal@24476 555 ReadSectorNext:
pascal@24476 556 adc dx, bx
pascal@24476 557 push di
pascal@24476 558 push cx
pascal@24476 559
pascal@25450 560 %if LBAsupport != 0
pascal@24476 561 push bx
pascal@24476 562 push bx
pascal@25450 563 %endif
pascal@24476 564 push dx ; 32-bit LBA: up to 2TB
pascal@24476 565 push ax
pascal@24476 566 push es
pascal@25450 567 %if ReadRetry != 0 || LBAsupport != 0
pascal@25450 568 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@25450 569 %endif
pascal@25450 570 %if LBAsupport != 0
pascal@24476 571 push bx
pascal@24476 572 inc bx ; sector count word = 1
pascal@24476 573 push bx
pascal@24476 574 dec bx
pascal@24476 575 push di
pascal@25450 576 %endif
pascal@24476 577
pascal@25450 578 %if Over2GB != 0
pascal@24476 579 xchg ax, cx ; save low LBA
pascal@24476 580 xchg ax, dx ; get high LBA
pascal@25452 581 cwd ; clear dx (LBA offset <1TB)
pascal@25450 582 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 583
pascal@24476 584 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25450 585 %else
pascal@25450 586 xor cx, cx ; up to 2GB disks otherwise divide error interrupt !
pascal@25450 587 %endif
pascal@25450 588 idiv word [bx(bpbSectorsPerTrack)]
pascal@24476 589 ; ax = LBA / SPT
pascal@24476 590 ; dx = LBA % SPT = sector - 1
pascal@24476 591 inc dx
pascal@24476 592
pascal@24476 593 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25450 594 idiv word [bx(bpbHeadsPerCylinder)]
pascal@24476 595 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 596 ; dx = (LBA / SPT) % HPC = head
pascal@25458 597
pascal@25458 598 xchg ch, al ; clear al
pascal@24476 599 ; ch = LSB 0...7 of cylinder no.
pascal@25458 600 shr ax, 1
pascal@25458 601 shr ax, 1
pascal@24476 602 or cl, al
pascal@24476 603 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 604 mov dh, dl
pascal@24476 605 ; dh = head no.
pascal@24476 606
pascal@24476 607 ReadSectorRetry:
pascal@25450 608 mov dl, [bx(DriveNumber)]
pascal@24476 609 ; dl = drive no.
pascal@25450 610 mov si, sp
pascal@25450 611 %if LBAsupport != 0
pascal@24476 612 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 613 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 614 jnc ReadSectorNextSegment
pascal@25450 615 %endif
pascal@24476 616
pascal@24476 617 mov ax, 201h ; al = sector count = 1
pascal@24476 618 ; ah = 2 = read function no.
pascal@24476 619 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 620
pascal@24476 621 jnc ReadSectorNextSegment
pascal@25450 622 %if ReadRetry != 0
pascal@24476 623 cbw ; ah = 0 = reset function
pascal@24476 624 int 13h ; reset drive (DL)
pascal@24476 625
pascal@24476 626 dec di
pascal@25457 627 jnz ReadSectorRetry ; up to 15 extra attempt
pascal@25450 628 %endif
pascal@24476 629
pascal@24476 630 call Error
pascal@24476 631 db "Read error."
pascal@24476 632
pascal@24476 633 ReadSectorNextSegment:
pascal@24476 634
pascal@25450 635 %if LBAsupport != 0
pascal@24476 636 pop ax ; al = 16
pascal@25458 637 %if SectorOf512Bytes != 0
pascal@25458 638 add word [si+6], byte 32 ; adjust segment for next sector
pascal@25458 639 %else
pascal@24476 640 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@25458 641 add [si+6], ax ; adjust segment for next sector
pascal@25458 642 %endif
pascal@24476 643 pop cx ; sector count = 1
pascal@24476 644 pop bx
pascal@25450 645 %else
pascal@25458 646 %if SectorOf512Bytes != 0
pascal@25458 647 add word [si], byte 32 ; adjust segment for next sector
pascal@25458 648 %else
pascal@25450 649 mov al, 16
pascal@25450 650 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@25450 651 add [si], ax ; adjust segment for next sector
pascal@25458 652 %endif
pascal@25450 653 %endif
pascal@24476 654 pop es ; es:0 updated
pascal@24476 655 pop ax
pascal@24476 656 pop dx
pascal@25450 657 %if LBAsupport != 0
pascal@24476 658 pop di
pascal@24476 659 pop di
pascal@24476 660 add ax, cx ; adjust LBA for next sector
pascal@25450 661 %else
pascal@25450 662 add ax, 1 ; adjust LBA for next sector
pascal@25450 663 %endif
pascal@24476 664
pascal@24476 665 pop cx ; cluster sectors to read
pascal@24476 666 pop di ; file sectors to read
pascal@24476 667 dec di ; keep C
pascal@25457 668 loopne ReadSectorNext ; until cluster sector count or file sector count
pascal@24476 669 pop si
pascal@24942 670 mov ax, bx ; clear ax
pascal@25450 671 mov dx, [bx(DriveNumber)] ; pass the BIOS boot drive to Run or Error
pascal@24476 672
pascal@24476 673 ret
pascal@24476 674
pascal@24942 675 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 676 ;; Fill free space with zeroes ;;
pascal@24942 677 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 678
pascal@25458 679 times (512-13-($-$$)) db 0
pascal@24476 680
pascal@24476 681 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 682 ;; Name of the file to load and run ;;
pascal@24476 683 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 684
pascal@25463 685 NameLength equ 11
pascal@25463 686 ProgramName times NameLength db 0 ; name and extension
pascal@24476 687
pascal@24476 688 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 689 ;; End of the sector ID ;;
pascal@24476 690 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 691
pascal@24476 692 ClusterList dw 0AA55h ; BIOS checks for this ID