wok annotate BootProg/stuff/boot16.asm @ rev 25225

updated python-pyflakes (2.1.1 -> 2.4.0)
author Hans-G?nter Theisgen
date Wed Jul 13 16:33:48 2022 +0100 (2022-07-13)
parents 180119c209e8
children 62d43c1b8453
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - FAT12 and FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; - cpu 8086 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@24476 29 ;; Known Bugs: ;;
pascal@24476 30 ;; ~~~~~~~~~~~ ;;
pascal@24476 31 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 32 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 33 ;; - 360KB 5"25 ;;
pascal@24476 34 ;; - 1.2MB 5"25 ;;
pascal@24476 35 ;; - 1.44MB 3"5 ;;
pascal@24476 36 ;; on my HDD (FAT16). ;;
pascal@24476 37 ;; ;;
pascal@24476 38 ;; ;;
pascal@24476 39 ;; Memory Layout: ;;
pascal@24476 40 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 41 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 42 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 43 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 44 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; physical address ;;
pascal@24476 47 ;; +------------------------+ 00000H ;;
pascal@24476 48 ;; | Interrupt Vector Table | ;;
pascal@24476 49 ;; +------------------------+ 00400H ;;
pascal@24476 50 ;; | BIOS Data Area | ;;
pascal@24476 51 ;; +------------------------+ 00500H ;;
pascal@24476 52 ;; | PrtScr Status / Unused | ;;
pascal@24476 53 ;; +------------------------+ 00600H ;;
pascal@24476 54 ;; | Loaded Image | ;;
pascal@24476 55 ;; +------------------------+ nnnnnH ;;
pascal@24476 56 ;; | Available Memory | ;;
pascal@24476 57 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 58 ;; | Boot Sector | ;;
pascal@24476 59 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 60 ;; | 3KB Boot Stack | ;;
pascal@24476 61 ;; +------------------------+ A0000H ;;
pascal@24476 62 ;; | Video RAM | ;;
pascal@24476 63 ;; ;;
pascal@24476 64 ;; ;;
pascal@24476 65 ;; Boot Image Startup (register values): ;;
pascal@24476 66 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 67 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24945 68 ;; bx = cx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 69 ;; cs:ip = program entry point ;;
pascal@24476 70 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 71 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 72 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 73 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 74 ;; Magic numbers: ;;
pascal@24476 75 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 76 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 77 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 78 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 79 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 80 ;; metal and MS-DOS programs. ;;
pascal@24945 81 ;; The command line contains no arguments. ;;
pascal@24476 82 ;; ;;
pascal@24476 83 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 84
pascal@24476 85 %define bx(label) bx+label-boot
pascal@24476 86
pascal@24476 87 [BITS 16]
pascal@24476 88 [CPU 8086]
pascal@24476 89
pascal@24476 90 ImageLoadSeg equ 60h
pascal@24476 91 StackSize equ 3072 ; Stack + cluster list
pascal@24476 92
pascal@24476 93 [SECTION .text]
pascal@24476 94 [ORG 0]
pascal@24476 95
pascal@24476 96 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 97 ;; Boot sector starts here ;;
pascal@24476 98 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 99
pascal@24476 100 boot:
pascal@24476 101 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 102 nop
pascal@24476 103 bsOemName DB "BootProg" ; 0x03
pascal@24476 104
pascal@24476 105 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 106 ;; BPB starts here ;;
pascal@24476 107 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 108
pascal@24479 109 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 110 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 111 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 112 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 113 bpbRootEntries DW 0 ; 0x11
pascal@24479 114 bpbTotalSectors DW 0 ; 0x13
pascal@24479 115 bpbMedia DB 0 ; 0x15
pascal@24479 116 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 117 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 118 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 119 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 120 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 121
pascal@24476 122 ;;;;;;;;;;;;;;;;;;;
pascal@24476 123 ;; BPB ends here ;;
pascal@24476 124 ;;;;;;;;;;;;;;;;;;;
pascal@24476 125
pascal@24479 126 bsDriveNumber DB 0 ; 0x24
pascal@24479 127 bsUnused DB 0 ; 0x25
pascal@24479 128 bsExtBootSignature DB 0 ; 0x26
pascal@24479 129 bsSerialNumber DD 0 ; 0x27
pascal@24476 130 bsVolumeLabel DB "NO NAME " ; 0x2B
pascal@24476 131 bsFileSystem DB "FAT12 " ; 0x36
pascal@24476 132
pascal@24476 133 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 134 ;; Boot sector code starts here ;;
pascal@24476 135 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 136
pascal@24476 137 start:
pascal@24476 138 cld
pascal@24476 139
pascal@24476 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 141 ;; How much RAM is there? ;;
pascal@24476 142 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 143
pascal@24476 144 int 12h ; get conventional memory size (in KBs)
pascal@24476 145 mov cx, 106h
pascal@24476 146 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 147
pascal@24476 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 149 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 151
pascal@24476 152 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 153 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 154 mov ss, ax
pascal@24476 155 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 156
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158 ;; Copy ourselves to top of memory ;;
pascal@24476 159 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 160
pascal@24476 161 mov si, 7C00h
pascal@24476 162 xor di, di
pascal@24476 163 mov ds, di
pascal@24476 164 mov [si], dx ; store BIOS boot drive number
pascal@24476 165 rep movsw ; move 512 bytes (+ 12)
pascal@24476 166
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 168 ;; Jump to the copy ;;
pascal@24476 169 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 170
pascal@24476 171 push es
pascal@24476 172 mov cl, byte main
pascal@24476 173 push cx
pascal@24476 174 retf
pascal@24476 175
pascal@24476 176 main:
pascal@24476 177 %if ImageLoadSeg != main-boot
pascal@24476 178 %if ImageLoadSeg >= 100h
pascal@24476 179 mov cx, ImageLoadSeg
pascal@24476 180 %else
pascal@24476 181 mov cl, ImageLoadSeg
pascal@24476 182 %endif
pascal@24476 183 %endif
pascal@24476 184 push cx
pascal@24476 185
pascal@24476 186 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 187 ;; Get drive parameters ;;
pascal@24476 188 ;; Update heads count ;;
pascal@24476 189 ;; for current BIOS ;;
pascal@24476 190 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 191
pascal@24476 192 mov ah, 8
pascal@24476 193 int 13h ; may destroy SI,BP, and DS registers
pascal@24476 194 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 195 push cs
pascal@24476 196 pop ds
pascal@24476 197 xor bx, bx
pascal@24476 198
pascal@24479 199 and cx, byte 3Fh
pascal@24476 200 cmp [bx(bpbSectorsPerTrack)], cx
pascal@24476 201 jne BadParams ; verify updated and validity
pascal@24476 202 mov al, dh
pascal@24476 203 inc ax
pascal@24476 204 mov [bpbHeadsPerCylinder], ax
pascal@24476 205 BadParams:
pascal@24476 206
pascal@24476 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 208 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 209 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 210
pascal@24476 211 pop es ; ImageLoadSeg
pascal@24476 212 push es
pascal@24476 213
pascal@24476 214 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@24476 215 mov cx, word [bx(bpbSectorsPerFAT)]
pascal@24476 216
pascal@24945 217 call ReadCXSectors ; read fat and clear ax & cx; bp = SectorsPerFAT
pascal@24476 218
pascal@24476 219 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 220 ;; load the root directory in ;;
pascal@24476 221 ;; its entirety (16KB max) ;;
pascal@24476 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 223
pascal@24942 224 mov al, 32
pascal@24476 225
pascal@24476 226 mul word [bx(bpbRootEntries)]
pascal@24476 227 div word [bx(bpbBytesPerSector)]
pascal@24476 228 xchg ax, cx ; cx = root directory size in sectors, clear ax
pascal@24476 229
pascal@24476 230 mov al, [bpbNumberOfFATs]
pascal@24476 231 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadCXSectors
pascal@24476 232
pascal@24476 233 push es
pascal@24945 234 call ReadCXSectors ; read root directory; clear ax, cx & di; bp = first data sector
pascal@24476 235 pop es
pascal@24476 236
pascal@24476 237 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 238 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 239 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 240
pascal@24476 241 ; es:di -> root entries array
pascal@24476 242
pascal@24476 243 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 244 ;; Looks for the file/dir ProgramName ;;
pascal@24476 245 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 246 ;; Input: ES:DI -> root directory array ;;
pascal@24476 247 ;; Output: SI = cluster number ;;
pascal@24476 248 ;; AX = file sector count ;;
pascal@24476 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 250
pascal@24476 251 FindNameCycle:
pascal@24476 252 push di
pascal@24476 253 mov cl, 11
pascal@24476 254 mov si, ProgramName ; ds:si -> program name
pascal@24476 255 repe cmpsb
pascal@24476 256 pop di
pascal@24476 257 je FindNameFound
pascal@24942 258 scasb
pascal@24942 259 je FindNameFailed ; end of root directory (NULL entry found)
pascal@24942 260 add di, byte 31
pascal@24476 261 dec word [bx(bpbRootEntries)]
pascal@24476 262 jnz FindNameCycle ; next root entry
pascal@24476 263
pascal@24476 264 FindNameFailed:
pascal@24476 265 call Error
pascal@24476 266 db "File not found."
pascal@24476 267
pascal@24476 268 FindNameFound:
pascal@24476 269 push si
pascal@24476 270 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 271 les ax, [es:di+1Ch] ; file size
pascal@24476 272 mov dx, es
pascal@24476 273 div word [bx(bpbBytesPerSector)]
pascal@24476 274 cmp bx, dx ; sector aligned ?
pascal@24476 275 adc ax, bx ; file last sector
pascal@24476 276 pop di ; di = ClusterList
pascal@24476 277
pascal@24476 278 pop es ; ImageLoadSeg
pascal@24476 279 push ax
pascal@24476 280
pascal@24476 281 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 282 ;; build cluster list ;;
pascal@24476 283 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 284 ;; Input: ES:0 -> FAT ;;
pascal@24476 285 ;; SI = first cluster ;;
pascal@24476 286 ;; DI = cluster list :;
pascal@24476 287 ;; CH = 0 ;;
pascal@24476 288 ;; Output: SI = cluster list ;;
pascal@24476 289 ;; CH = 0 ;;
pascal@24476 290 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 291
pascal@24476 292 push di ; up to 2 * 635K / BytesPerCluster bytes
pascal@24476 293 mov cl, 12
pascal@24476 294 ClusterLoop:
pascal@24476 295 mov [di], si
pascal@24476 296
pascal@24476 297 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@24476 298 add si, si ; si = cluster * 2
pascal@25094 299 jnc First64k
pascal@24476 300 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@25094 301 First64k:
pascal@24942 302 mov dx, 0FFF8h
pascal@24942 303
pascal@24476 304 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@24942 305 ja ReadClusterFat16
pascal@24476 306
pascal@24942 307 mov dh, 0Fh
pascal@25087 308 add si, [di]
pascal@24476 309 shr si, 1 ; si = cluster * 3 / 2
pascal@24476 310
pascal@24942 311 ReadClusterFat16:
pascal@25094 312 push ds
pascal@25087 313 mov ds, ax
pascal@24476 314 lodsw ; ax = next cluster
pascal@25094 315 pop ds
pascal@24476 316 jnc ReadClusterEven
pascal@24476 317
pascal@24476 318 rol ax, cl
pascal@24476 319
pascal@24476 320 ReadClusterEven:
pascal@25094 321 scasw ; di += 2
pascal@24942 322 and ah, dh ; mask cluster value
pascal@24942 323 cmp ax, dx
pascal@24476 324
pascal@24476 325 xchg ax, si
pascal@24476 326 jc ClusterLoop
pascal@24476 327 pop si
pascal@24476 328 pop di ; file size in sectors
pascal@24476 329
pascal@24476 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 331 ;; Load the entire file ;;
pascal@24476 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 333 ;; Input: ES:0 -> buffer ;;
pascal@24476 334 ;; SI = cluster list ;;
pascal@24476 335 ;; DI = file sectors ;;
pascal@24476 336 ;; CH = 0 ;;
pascal@24945 337 ;; BP = 1st data sec ;;
pascal@24476 338 ;; Output: BP:0 -> buffer ;;
pascal@24476 339 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 340
pascal@24476 341 push es
pascal@24476 342
pascal@24476 343 ReadClusters:
pascal@24476 344 lodsw
pascal@24476 345 dec ax
pascal@24476 346 dec ax
pascal@24476 347
pascal@24476 348 mov cl, [bx(bpbSectorsPerCluster)]
pascal@24476 349 mul cx ; cx = sector count (ch = 0)
pascal@24476 350
pascal@24476 351 add ax, bp ; LBA for cluster data
pascal@24476 352 adc dx, bx ; dx:ax = LBA
pascal@24476 353
pascal@24942 354 call ReadSector ; clear ax & cx, restore dx
pascal@24476 355
pascal@24476 356 jne ReadClusters
pascal@24476 357
pascal@24476 358 pop bp ; ImageLoadSeg
pascal@24476 359
pascal@24476 360 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 361 ;; Type detection, .COM or .EXE? ;;
pascal@24476 362 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 363
pascal@24476 364 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 365
pascal@24476 366 add bp, [bx+08h] ; bp = image base
pascal@24476 367 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 368
pascal@24476 369 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 370 je RelocateEXE ; yes, it's an EXE program
pascal@24476 371
pascal@24476 372 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 373 ;; Setup and run a .COM program ;;
pascal@24476 374 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24942 375 ;; AX=0ffffh BX=0 CX=0 DX=drive ;;
pascal@24942 376 ;; and cmdline=void ;;
pascal@24476 377 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 378
pascal@24942 379 mov di, 100h ; ip
pascal@24476 380 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 381 mov ss, bp
pascal@24476 382 xor sp, sp
pascal@24476 383 push bp ; cs, ds and es
pascal@24476 384 jmp short Run
pascal@24476 385
pascal@24476 386 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 387 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 388 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 389 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24942 390 ;; AX=0ffffh BX=0 CX=0 DX=drive cmdline=void ;;
pascal@24476 391 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 392
pascal@24476 393 ReloCycle:
pascal@24476 394 add [di+2], bp ; item seg (abs)
pascal@24476 395 les si, [di] ; si = item ofs, es = item seg
pascal@24476 396 add [es:si], bp ; fixup
pascal@24476 397 scasw ; di += 2
pascal@24476 398 scasw ; point to next entry
pascal@24476 399
pascal@24476 400 RelocateEXE:
pascal@24942 401 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 402 jns ReloCycle
pascal@24476 403 ; PSP don't have a valid drive identifier
pascal@24476 404 les si, [bx+0Eh]
pascal@24476 405 add si, bp
pascal@24476 406 mov ss, si ; ss for EXE
pascal@24476 407 mov sp, es ; sp for EXE
pascal@24476 408
pascal@24476 409 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 410 push si ; containing the PSP structure
pascal@24476 411
pascal@24476 412 add bp, [bx+16h] ; cs for EXE
pascal@24942 413 mov di, [bx+14h] ; ip for EXE
pascal@24476 414 Run:
pascal@24476 415 pop ds
pascal@24476 416 push bp
pascal@24942 417 push di
pascal@24476 418 push ds
pascal@24476 419 pop es
pascal@24942 420 mov [80h], ax ; clear cmdline
pascal@24942 421 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 422
pascal@24476 423 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 424 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 425 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 426 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 427 mov si, 16381 ; prime number 2**14-3
pascal@24476 428 mov di, 32749 ; prime number 2**15-19
pascal@24476 429 mov bp, 65521 ; prime number 2**16-15
pascal@24476 430
pascal@24476 431 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 432 ;; All done, transfer control to the program now ;;
pascal@24476 433 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 434 retf
pascal@24476 435
pascal@24476 436 ReadCXSectors:
pascal@24476 437 mov bp, cx
pascal@24476 438 add bp, ax ; adjust LBA for cluster data
pascal@24476 439
pascal@24476 440 mov di, cx ; no file size limit
pascal@24476 441
pascal@24476 442 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 443 ;; Reads sectors using BIOS Int 13h ;;
pascal@24476 444 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 445 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 446 ;; BX = 0 ;;
pascal@24476 447 ;; CX = sector count ;;
pascal@24476 448 ;; DI = file sectors ;;
pascal@24476 449 ;; ES:BX -> buffer address ;;
pascal@24476 450 ;; Output: ES:BX -> next address ;;
pascal@24476 451 ;; BX = 0 ;;
pascal@24476 452 ;; CX or DI = 0 ;;
pascal@24476 453 ;; DL = drive number ;;
pascal@24476 454 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 455
pascal@24476 456 ReadSector:
pascal@24476 457 add ax, [bx(bpbHiddenSectors)]
pascal@24476 458 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 459 add ax, [bx(bpbReservedSectors)]
pascal@24476 460
pascal@24476 461 push si
pascal@24476 462 ReadSectorNext:
pascal@24476 463 adc dx, bx
pascal@24476 464 push di
pascal@24476 465 push cx
pascal@24476 466
pascal@24476 467 push bx
pascal@24476 468 push bx
pascal@24476 469 push dx ; 32-bit LBA: up to 2TB
pascal@24476 470 push ax
pascal@24476 471 push es
pascal@24476 472 push bx
pascal@24476 473 inc bx ; sector count word = 1
pascal@24476 474 push bx
pascal@24476 475 dec bx
pascal@24476 476 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@24476 477 push di
pascal@24476 478
pascal@24476 479 xchg ax, cx ; save low LBA
pascal@24476 480 xchg ax, dx ; get high LBA
pascal@24476 481 cwd ; clear dx (LBA offset <2TB)
pascal@24476 482 div word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 483
pascal@24476 484 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@24476 485 div word [bx(bpbSectorsPerTrack)]
pascal@24476 486 ; ax = LBA / SPT
pascal@24476 487 ; dx = LBA % SPT = sector - 1
pascal@24476 488 inc dx
pascal@24476 489
pascal@24476 490 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@24476 491 div word [bx(bpbHeadsPerCylinder)]
pascal@24476 492 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 493 ; dx = (LBA / SPT) % HPC = head
pascal@24476 494 mov ch, al
pascal@24476 495 ; ch = LSB 0...7 of cylinder no.
pascal@24476 496 mov al, 64
pascal@24476 497 mul ah
pascal@24476 498 or cl, al
pascal@24476 499 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 500 mov dh, dl
pascal@24476 501 ; dh = head no.
pascal@24476 502
pascal@24476 503 ReadSectorRetry:
pascal@24476 504 mov dl, [bx]
pascal@24476 505 ; dl = drive no.
pascal@24476 506 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 507 mov si, sp
pascal@24476 508 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 509 jnc ReadSectorNextSegment
pascal@24476 510
pascal@24476 511 mov ax, 201h ; al = sector count = 1
pascal@24476 512 ; ah = 2 = read function no.
pascal@24476 513 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 514
pascal@24476 515 jnc ReadSectorNextSegment
pascal@24476 516 cbw ; ah = 0 = reset function
pascal@24476 517 int 13h ; reset drive (DL)
pascal@24476 518
pascal@24476 519 dec di
pascal@24476 520 jnz ReadSectorRetry ; extra attempt
pascal@24476 521
pascal@24476 522 call Error
pascal@24476 523 db "Read error."
pascal@24476 524
pascal@24476 525 ReadSectorNextSegment:
pascal@24476 526
pascal@24476 527 pop ax ; al = 16
pascal@24476 528 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@24476 529 pop cx ; sector count = 1
pascal@24476 530 pop bx
pascal@24476 531 add [si+6], ax ; adjust segment for next sector
pascal@24476 532 pop es ; es:0 updated
pascal@24476 533 pop ax
pascal@24476 534 pop dx
pascal@24476 535 pop di
pascal@24476 536 pop di
pascal@24476 537
pascal@24476 538 add ax, cx ; adjust LBA for next sector
pascal@24476 539
pascal@24476 540 pop cx ; cluster sectors to read
pascal@24476 541 pop di ; file sectors to read
pascal@24476 542 dec di ; keep C
pascal@24476 543 loopne ReadSectorNext ; until cluster sector count or file sector count is reached
pascal@24476 544 pop si
pascal@24942 545 mov ax, bx ; clear ax
pascal@24476 546 mov dx, [bx] ; pass the BIOS boot drive to Run or Error
pascal@24476 547
pascal@24476 548 ret
pascal@24476 549
pascal@24942 550 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 551 ;; Fill free space with zeroes ;;
pascal@24942 552 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 553
pascal@24942 554 times (512-13-20-($-$$)) db 0
pascal@24942 555
pascal@24476 556 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 557 ;; Error Messaging Code ;;
pascal@24476 558 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 559
pascal@24476 560 Error:
pascal@24476 561 pop si
pascal@24478 562
pascal@24478 563 PutStr:
pascal@24476 564 mov ah, 0Eh
pascal@24476 565 mov bl, 7
pascal@24476 566 lodsb
pascal@24476 567 int 10h
pascal@24476 568 cmp al, "."
pascal@24476 569 jne PutStr
pascal@24476 570
pascal@24476 571 cbw
pascal@24476 572 int 16h ; wait for a key...
pascal@24476 573 int 19h ; bootstrap
pascal@24476 574
pascal@24476 575 Stop:
pascal@24476 576 hlt
pascal@24476 577 jmp short Stop
pascal@24476 578
pascal@24476 579 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 580 ;; Name of the file to load and run ;;
pascal@24476 581 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 582
pascal@24476 583 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@24476 584 ; padded with spaces (11 bytes total)
pascal@24476 585
pascal@24476 586 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 587 ;; End of the sector ID ;;
pascal@24476 588 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 589
pascal@24476 590 ClusterList dw 0AA55h ; BIOS checks for this ID
pascal@24479 591