wok annotate ipxe/stuff/bootloader.S @ rev 20179

ipxe: update bootloader
author Pascal Bellard <pascal.bellard@slitaz.org>
date Sat Jan 27 12:56:10 2018 +0100 (2018-01-27)
parents
children 1421f93cc28a
rev   line source
pascal@20179 1 // Image/zImage & tiny bzImage linux kernel boot sector, (C) SliTaz, GPL2.
pascal@20179 2
pascal@20179 3 SYSSEG = 0x1000
pascal@20179 4 INITSEG = 0x9000
pascal@20179 5 SETUPSEG = 0x9020
pascal@20179 6 setup_sects = 497
pascal@20179 7 syssize = 500
pascal@20179 8 cmd_line_ptr = 0x228
pascal@20179 9
pascal@20179 10 .text
pascal@20179 11 .code16
pascal@20179 12 .org 0
pascal@20179 13 .globl _start
pascal@20179 14 _start:
pascal@20179 15
pascal@20179 16 #define CODESZ 512 /* patched by installer */
pascal@20179 17
pascal@20179 18 #define BZIMAGE 0x207 /* setup version ; for bzImage < 512 Kb only */
pascal@20179 19
pascal@20179 20 /* some extra features */
pascal@20179 21 #define EXE_SUPPORT real mode dos .exe file support
pascal@20179 22 #define CMDLINE kernel cmdline support
pascal@20179 23 #define VCPI VCPI 4.0 support
pascal@20179 24 #define SHUTDOWNDOS shutdown DOS services
pascal@20179 25
pascal@20179 26 /* some contraints to reduce the code size */
pascal@20179 27 //#define FLOPPY_1440K_ONLY 1.44M floppies support only -33
pascal@20179 28 //#define FLOPPY_HAS_2_SIDES hardcoded heads count to 2 -13
pascal@20179 29 //#define NO_CMDLINE_SHRINK remove heading spaces ? -6-20
pascal@20179 30 //#define NO_CMDLINE_FILE remove @cmdline file support ? -20
pascal@20179 31 #define NO_DOTS show progression dots ? -8
pascal@20179 32 #ifndef BZIMAGE
pascal@20179 33 //#defime NO_MINSETUP default setup (dos only) ? -4
pascal@20179 34 //#define NO_CURSOR_DEFINITION -8
pascal@20179 35 #endif
pascal@20179 36
pascal@20179 37 #ifdef EXE_SUPPORT
pascal@20179 38 #define EXEADRS(x) (x+0xE0)
pascal@20179 39 #define FLAT20(x) (x+16*INITSEG)
pascal@20179 40
pascal@20179 41 .macro trace_int19
pascal@20179 42 pushl $4
pascal@20179 43 popw %si
pascal@20179 44 popw %ds
pascal@20179 45 pushl (%si)
pascal@20179 46 movl $step19+(INITSEG<<16), (%si)
pascal@20179 47 pushfw
pascal@20179 48 popw %ax
pascal@20179 49 incb %ah # set TF
pascal@20179 50 pushw %ax
pascal@20179 51 popfw
pascal@20179 52 ljmp *4*0x19-4(%si)
pascal@20179 53 .endm
pascal@20179 54
pascal@20179 55 stacktop = 0x9E00 # in 0x8000 .. 0xA000
pascal@20179 56 decw %bp // Magic number: MZ
pascal@20179 57 popw %dx
pascal@20179 58 jmp start // Bytes on last page of file
pascal@20179 59 .word (CODESZ+511)/512 // Pages in file INSTALLER
pascal@20179 60 .word 0 // Relocations
pascal@20179 61 .word (end_header-_start)/16 // Size of header in paragraphs
pascal@20179 62 .word 4096 // Minimum extra paragraphs needed
pascal@20179 63 .word -1 // Maximum extra paragraphs needed
pascal@20179 64 .word (CODESZ+15)/16 // Initial (relative) SS value INSTALLER
pascal@20179 65 .word stacktop // Initial SP value
pascal@20179 66 .word 0 // Checksum INSTALLER?
pascal@20179 67 .word EXEADRS(comstart) // Initial IP value
pascal@20179 68 .word 0xFFF0 // Initial (relative) CS value
pascal@20179 69 // .word 0x001C // File address of relocation table
pascal@20179 70 // .word 0,0,0 // Overlay number
pascal@20179 71 #endif
pascal@20179 72 start:
pascal@20179 73 xorw %ax, %ax # %ax = 0
pascal@20179 74 #ifdef BZIMAGE
pascal@20179 75 zeroed = 14 # zeroed registers
pascal@20179 76 #else
pascal@20179 77 zeroed = 12 # zeroed registers
pascal@20179 78 #endif
pascal@20179 79 movw $zeroed/2, %cx # clear gdt + offset, %ds, limits
pascal@20179 80 stacktop = 0x9E00 # in 0x8000 .. 0xA000 (+zeroed+12)
pascal@20179 81 pushw $INITSEG
pascal@20179 82 end_header:
pascal@20179 83 cld # assume nothing
pascal@20179 84 #if defined(BZIMAGE) && BZIMAGE >= 0x202
pascal@20179 85 popw %es # %es contain INITSEG
pascal@20179 86 movw %es, %di
pascal@20179 87 #else
pascal@20179 88 # cmdline offset at 0x22
pascal@20179 89 movw $stacktop, %di # stacktop is an arbitrary value >=
pascal@20179 90 # length of bootsect + length of
pascal@20179 91 # setup + room for stack;
pascal@20179 92 # 12 is disk parm size.
pascal@20179 93 popw %es # %es contain INITSEG
pascal@20179 94 #endif
pascal@20179 95 pushw %es
pascal@20179 96 popw %ss # %es = %ss = INITSEG
pascal@20179 97 movw %di, %sp # put stack at INITSEG:stacktop-...
pascal@20179 98 #ifdef EXE_SUPPORT
pascal@20179 99 cwd # force %dx = 0 (floppy only)
pascal@20179 100 #endif
pascal@20179 101
pascal@20179 102 # Many BIOS's default disk parameter tables will not recognize
pascal@20179 103 # multi-sector reads beyond the maximum sector number specified
pascal@20179 104 # in the default diskette parameter tables - this may mean 7
pascal@20179 105 # sectors in some cases.
pascal@20179 106 #
pascal@20179 107 # Since single sector reads are slow and out of the question,
pascal@20179 108 # we must take care of this by creating new parameter tables
pascal@20179 109 # (for the first disk) in RAM. We can set the maximum sector
pascal@20179 110 # count to 36 - the most we will encounter on an ED 2.88.
pascal@20179 111 #
pascal@20179 112 # High doesn't hurt. Low does. Let's use the max: 63
pascal@20179 113
pascal@20179 114 rep # don't worry about cld
pascal@20179 115 stosw # already done above
pascal@20179 116 popw %bx # offset = 0
pascal@20179 117 popw %ds # %ds = 0
pascal@20179 118 popw %fs # %fs = 0
pascal@20179 119
pascal@20179 120 movb setup_sects+0x7C00, %al # read bootsector + setup (%ds = 0)
pascal@20179 121 incw %ax
pascal@20179 122
pascal@20179 123 ldsw 0x78(%bx), %si # %ds:%bx+0x78 is parameter table address
pascal@20179 124 pushw %es
pascal@20179 125 pushw %di
pascal@20179 126 movb $6, %cl # copy 12 bytes
pascal@20179 127 rep # don't worry about cld
pascal@20179 128 movsw # already done above
pascal@20179 129 pushw %ss
pascal@20179 130 popw %ds # now %ds = %es = %ss = INITSEG
pascal@20179 131 popl %fs:0x78(%bx) # update parameter table address
pascal@20179 132 movb $63, 0x4-12(%di) # patch sector count, %di = stacktop
pascal@20179 133 cli
pascal@20179 134
pascal@20179 135 xchg %ax, %di # sector count
pascal@20179 136 popw %ax # limits = 0
pascal@20179 137 incw %cx # cylinder 0, sector 1, clear Z
pascal@20179 138 call read_first_sectors # read setup
pascal@20179 139
pascal@20179 140 # This routine loads the system at address LOADSEG, making sure
pascal@20179 141 # no 64kB boundaries are crossed. We try to load it as fast as
pascal@20179 142 # possible, loading whole tracks whenever we can.
pascal@20179 143
pascal@20179 144 #ifndef NO_DOTS
pascal@20179 145 popw %bx # clear %bx
pascal@20179 146 #endif
pascal@20179 147 movw syssize, %di
pascal@20179 148 decw %di
pascal@20179 149 shrw $9-4, %di
pascal@20179 150 incw %di
pascal@20179 151 movw $SYSSEG, %cx
pascal@20179 152 #ifdef BZIMAGE
pascal@20179 153 push %cx
pascal@20179 154 #endif
pascal@20179 155 call read_sectorsCX
pascal@20179 156
pascal@20179 157 # This procedure turns off the floppy drive motor, so
pascal@20179 158 # that we enter the kernel in a known state, and
pascal@20179 159 # don't have to worry about it later.
pascal@20179 160
pascal@20179 161 kill_motor:
pascal@20179 162 xchgw %ax, %di # reset FDC (%di < 128)
pascal@20179 163 int $0x13
pascal@20179 164
pascal@20179 165 # After that (everything loaded), we jump to the setup-routine
pascal@20179 166 # loaded directly after the bootblock:
pascal@20179 167 # Segments are as follows: %ds = %ss = INITSEG
pascal@20179 168
pascal@20179 169 #ifdef BZIMAGE
pascal@20179 170 popw %bx
pascal@20179 171 popw %si // SYSSEG:0
pascal@20179 172 movesys: // %bx = DS, %si
pascal@20179 173 movw $16, %ax
pascal@20179 174 mulw %bx
pascal@20179 175 addw %si, %ax
pascal@20179 176 adcw $0x9300, %dx // %dx:%ax src flat address
pascal@20179 177 movw $9, %cx
pascal@20179 178 zero1:
pascal@20179 179 pushw $0 // 2E..1E
pascal@20179 180 loop zero1
pascal@20179 181 //pushl $0x93100000 // 1A: dest
pascal@20179 182 pushw $0x9310
pascal@20179 183 pushw %cx
pascal@20179 184 pushw $-1 // 18
pascal@20179 185 pushw %cx // 16
pascal@20179 186 pushw %dx // src
pascal@20179 187 pushw %ax
pascal@20179 188 pushw $-1 // 10
pascal@20179 189 movb $8, %cl
pascal@20179 190 movw %cx, %bx // will move 8*64 = 512Kb
pascal@20179 191 zero2:
pascal@20179 192 pushw $0 // 0E..00
pascal@20179 193 loop zero2
pascal@20179 194 movw %sp, %si
pascal@20179 195 pushw %ss
pascal@20179 196 popw %es
pascal@20179 197 pushw %es
pascal@20179 198 popw %ds
pascal@20179 199 syslp:
pascal@20179 200 movb $0x80, %ch
pascal@20179 201 movb $0x87, %ah
pascal@20179 202 int $0x15
pascal@20179 203 incb 0x14(%si)
pascal@20179 204 incb 0x1C(%si)
pascal@20179 205 decw %bx
pascal@20179 206 jne syslp
pascal@20179 207 #endif
pascal@20179 208 jmp_setup:
pascal@20179 209 ljmp $SETUPSEG, $0
pascal@20179 210
pascal@20179 211 #ifdef EXE_SUPPORT
pascal@20179 212 #ifdef SHUTDOWNDOS
pascal@20179 213 doiret:
pascal@20179 214 iret
pascal@20179 215 step19:
pascal@20179 216 pushw %si
pascal@20179 217 pushw %ds
pascal@20179 218 movw %sp, %si
pascal@20179 219 ldsw %ss:4(%si), %si
pascal@20179 220 cmpw $0x19CD, (%si)
pascal@20179 221 popw %ds
pascal@20179 222 popw %si
pascal@20179 223 jne doiret
pascal@20179 224 xorw %si, %si
pascal@20179 225 movw %si, %ds
pascal@20179 226 pushw %cs
pascal@20179 227 popw %ss
pascal@20179 228 movw $stacktop-4-16, %sp
pascal@20179 229 popl 4(%si)
pascal@20179 230 popaw
pascal@20179 231 #ifdef BZIMAGE
pascal@20179 232 jmp movesys
pascal@20179 233 #endif
pascal@20179 234 #endif
pascal@20179 235 #ifndef BZIMAGE
pascal@20179 236 movesys: // %ax = SYSSEG, %bx = DS, %si
pascal@20179 237 shrw $4, %si
pascal@20179 238 addw %si, %bx
pascal@20179 239 subw %ax, %bx
pascal@20179 240 jnc forward
pascal@20179 241 movb $0x90, %ah
pascal@20179 242 ;decw %ax
pascal@20179 243 forward:
pascal@20179 244 movw %ax, %es
pascal@20179 245 movw %ax, %di
pascal@20179 246 addw %bx, %di
pascal@20179 247 movw %di, %ds
pascal@20179 248 sbbw %di, %di // %di = 0 : -1
pascal@20179 249 cmc // C = 1 : 0
pascal@20179 250 adcw %di, %ax
pascal@20179 251 xorw %si, %si
pascal@20179 252 xorw %di, %di
pascal@20179 253 movb $0x10, %cl
pascal@20179 254 cmpb %cl, %ah // move 512k
pascal@20179 255 rep
pascal@20179 256 movsb
pascal@20179 257 jns forward
pascal@20179 258 #ifndef NO_CURSOR_DEFINITION
pascal@20179 259 movb $1, %ah
pascal@20179 260 movb $0, %bh
pascal@20179 261 movb $0x20, %ch // 0x2000
pascal@20179 262 int $0x10
pascal@20179 263 #endif
pascal@20179 264 pushw %ss
pascal@20179 265 popw %ds
pascal@20179 266 jmp jmp_setup
pascal@20179 267 #endif
pascal@20179 268 comstart:
pascal@20179 269 cld # assume nothing
pascal@20179 270 pushw $INITSEG
pascal@20179 271 popw %es
pascal@20179 272 #ifdef CMDLINE
pascal@20179 273 movw %sp, %di
pascal@20179 274 movw $0x80, %si
pascal@20179 275 lodsb
pascal@20179 276 cbw
pascal@20179 277 xchgw %ax, %cx
pascal@20179 278 jcxz nocmdline
pascal@20179 279 # if defined(BZIMAGE) && BZIMAGE >= 0x202
pascal@20179 280 movw $INITSEG/16+stacktop/256, EXEADRS(cmd_line_ptr+1)
pascal@20179 281 # else
pascal@20179 282 movw $0xA33F, 0x7F(%si)
pascal@20179 283 # endif
pascal@20179 284 # ifndef NO_CMDLINE_SHRINK
pascal@20179 285 skipspace:
pascal@20179 286 lodsb
pascal@20179 287 cmpb $0x20, %al
pascal@20179 288 je skipspace
pascal@20179 289 # ifndef NO_CMDLINE_FILE
pascal@20179 290 movw %si,%dx
pascal@20179 291 decw %si
pascal@20179 292 subb $'@',%al
pascal@20179 293 jne notafile
pascal@20179 294 movb $0x3D,%ah
pascal@20179 295 int $0x21
pascal@20179 296 jc notafile
pascal@20179 297 xchgw %ax,%bx
pascal@20179 298 //movw %si,%dx // ~320 bytes max
pascal@20179 299 movw $EXEADRS(notafile)-130,%cx
pascal@20179 300 movb $0x3F,%ah
pascal@20179 301 int $0x21
pascal@20179 302 xchgw %ax,%cx
pascal@20179 303 notafile:
pascal@20179 304 # else
pascal@20179 305 decw %si
pascal@20179 306 # endif
pascal@20179 307 # endif
pascal@20179 308 rep
pascal@20179 309 movsb
pascal@20179 310 nocmdline:
pascal@20179 311 orb EXEADRS(setup_sects), %ch
pascal@20179 312 # ifndef NO_MINSETUP
pascal@20179 313 # ifndef BZIMAGE
pascal@20179 314 jnz setupok
pascal@20179 315 mov $4, %ch
pascal@20179 316 setupok:
pascal@20179 317 # endif
pascal@20179 318 # endif
pascal@20179 319 #else
pascal@20179 320 movb EXEADRS(setup_sects), %ch
pascal@20179 321 #endif
pascal@20179 322 movb $(512-(end_header-_start))/2, %cl
pascal@20179 323 movw $0x100, %si
pascal@20179 324 movw $end_header, %di
pascal@20179 325 rep
pascal@20179 326 movsw
pascal@20179 327 movw $SYSSEG, %ax
pascal@20179 328 movw %ds, %bx
pascal@20179 329 pushw %es
pascal@20179 330 popw %ss
pascal@20179 331 #ifndef SHUTDOWNDOS
pascal@20179 332 pushw %es
pascal@20179 333 pushw $movesys
pascal@20179 334 #endif
pascal@20179 335 #ifdef VCPI
pascal@20179 336 pushaw
pascal@20179 337 smsww %ax
pascal@20179 338 andb $1, %al
pascal@20179 339 je isrm
pascal@20179 340 movw $EXEADRS(gdt_vcpi),%si
pascal@20179 341 movw $pagebuf-0x90000,%di // %es = 0x9000
pascal@20179 342 movl $pagebuf+3,%es:0x1000(%di)
pascal@20179 343 call_vcpi:
pascal@20179 344 movb $0xDE,%ah // DE01, EBX = getiface(DS:SI, ES:DI)
pascal@20179 345 int $0x67
pascal@20179 346 movl $FLAT20(sw2pm_params),%esi
pascal@20179 347 movb $0x0C,%al // DE0C switchpm(ESI)
pascal@20179 348 cli
pascal@20179 349 jmp call_vcpi
pascal@20179 350 pm_code:
pascal@20179 351 movl %cr0,%eax
pascal@20179 352 andl $0x7FFFFFFE,%eax
pascal@20179 353 movl %eax,%cr0
pascal@20179 354 movl %eax,%cr3
pascal@20179 355 isrm:
pascal@20179 356 # ifdef SHUTDOWNDOS
pascal@20179 357 trace_int19
pascal@20179 358 # else
pascal@20179 359 lssw %cs:EXEADRS(saved_ss_sp),%sp
pascal@20179 360 popaw
pascal@20179 361 retf
pascal@20179 362 # endif
pascal@20179 363 #else
pascal@20179 364 # ifdef SHUTDOWNDOS
pascal@20179 365 pushaw
pascal@20179 366 trace_int19
pascal@20179 367 # endif
pascal@20179 368 retf
pascal@20179 369 #endif
pascal@20179 370 #endif
pascal@20179 371
pascal@20179 372 # read_sectors reads %di sectors into %es:0 buffer.
pascal@20179 373 # %es:0 is updated to the next memory location.
pascal@20179 374 # First, sectors are read sector by sector until
pascal@20179 375 # sector per track count is known. Then they are
pascal@20179 376 # read track by track.
pascal@20179 377 # Assume no error on first track.
pascal@20179 378
pascal@20179 379 #ifdef FLOPPY_1440K_ONLY
pascal@20179 380 #define FLOPPY_HAS_2_SIDES hardcore heads count to 2
pascal@20179 381 #define FLOPPY_SECTORS 18 /* 18 sectors */
pascal@20179 382 #else
pascal@20179 383 #define FLOPPY_HEADS 2 /* 2 heads minimum */
pascal@20179 384 #endif
pascal@20179 385
pascal@20179 386 return:
pascal@20179 387 #ifndef NO_DOTS
pascal@20179 388 movw $0xE2E,%ax
pascal@20179 389 movb $7,%bl
pascal@20179 390 int $0x10
pascal@20179 391 #endif
pascal@20179 392 ret
pascal@20179 393
pascal@20179 394 check_limits:
pascal@20179 395 #ifndef FLOPPY_1440K_ONLY
pascal@20179 396 popw %dx
pascal@20179 397 cmpb %al, %cl # max sector known ?
pascal@20179 398 ja next_head # no -> store it
pascal@20179 399 #ifndef FLOPPY_HAS_2_SIDES
pascal@20179 400 #ifdef FLOPPY_HEADS
pascal@20179 401 cmpb $FLOPPY_HEADS, %dh # 2 heads minimum
pascal@20179 402 jb check_cylinder
pascal@20179 403 #endif
pascal@20179 404 cmpb %ah, %dh # max head known ?
pascal@20179 405 ja next_cylinder # no -> store it
pascal@20179 406 check_cylinder:
pascal@20179 407 #endif
pascal@20179 408 #endif
pascal@20179 409 pushaw
pascal@20179 410 #ifndef FLOPPY_1440K_ONLY
pascal@20179 411 cbw # %ah = 0
pascal@20179 412 #endif
pascal@20179 413 int $0x13 # reset controler
pascal@20179 414 popaw
pascal@20179 415 movb $1, %al # sector by sector...
pascal@20179 416 read_sectorslp:
pascal@20179 417 pushw %dx # some bios break dx...
pascal@20179 418 #ifndef FLOPPY_1440K_ONLY
pascal@20179 419 pushw %ax # limits
pascal@20179 420 subb %cl, %al # sectors remaining in track
pascal@20179 421 ja tolastsect
pascal@20179 422 movb $1, %al # 1 sector mini
pascal@20179 423 tolastsect:
pascal@20179 424 #else
pascal@20179 425 movb $FLOPPY_SECTORS+1, %al
pascal@20179 426 subb %cl, %al # sectors remaining in track
pascal@20179 427 #endif
pascal@20179 428 cbw
pascal@20179 429 cmpw %di, %ax
pascal@20179 430 jb more1trk
pascal@20179 431 movw %di, %ax # sectors to read
pascal@20179 432 more1trk:
pascal@20179 433 pushw %ax # save context
pascal@20179 434 movb $2, %ah # cmd: read chs
pascal@20179 435 int $0x13
pascal@20179 436 #ifndef FLOPPY_1440K_ONLY
pascal@20179 437 popw %dx # save %ax
pascal@20179 438 popw %ax # limits
pascal@20179 439 #else
pascal@20179 440 popw %ax # restore context
pascal@20179 441 popw %dx
pascal@20179 442 #endif
pascal@20179 443 jc check_limits
pascal@20179 444 #ifndef FLOPPY_1440K_ONLY
pascal@20179 445 xchgw %ax, %bp
pascal@20179 446 addw %dx,%cx # next sector
pascal@20179 447 movw %cx, %gs
pascal@20179 448 movw %es, %cx
pascal@20179 449 pushw %dx
pascal@20179 450 shlw $5, %dx
pascal@20179 451 addw %dx, %cx
pascal@20179 452 popw %dx
pascal@20179 453 subw %dx,%di # update sector counter
pascal@20179 454 popw %dx
pascal@20179 455 #else
pascal@20179 456 addw %ax,%cx # next sector
pascal@20179 457 movw %cx, %gs
pascal@20179 458 movw %es, %cx
pascal@20179 459 pushw %ax
pascal@20179 460 shlw $5, %ax
pascal@20179 461 addw %ax, %cx
pascal@20179 462 popw %ax
pascal@20179 463 subw %ax,%di # update sector counter
pascal@20179 464 #endif
pascal@20179 465 read_sectorsCX:
pascal@20179 466 movw %cx, %es # next location
pascal@20179 467 jz return
pascal@20179 468 read_sectors:
pascal@20179 469 movw %gs, %cx
pascal@20179 470 #ifndef FLOPPY_1440K_ONLY
pascal@20179 471 # al is last sector+1
pascal@20179 472 # ah is last cylinder+1
pascal@20179 473 xchgw %ax, %bp
pascal@20179 474 #endif
pascal@20179 475 #ifndef FLOPPY_1440K_ONLY
pascal@20179 476 cmpb %al,%cl # reach sector limit ?
pascal@20179 477 jne bdendlp
pascal@20179 478 next_head:
pascal@20179 479 movb %cl,%al
pascal@20179 480 #else
pascal@20179 481 cmpb $FLOPPY_SECTORS+1,%cl # reach sector limit ?
pascal@20179 482 jne bdendlp
pascal@20179 483 #endif
pascal@20179 484 movb $1,%cl # first sector
pascal@20179 485 #ifndef FLOPPY_HAS_2_SIDES
pascal@20179 486 incb %dh # next head
pascal@20179 487 cmpb %ah, %dh # reach head limit ?
pascal@20179 488 jne bdendlp
pascal@20179 489 next_cylinder:
pascal@20179 490 movb %dh,%ah
pascal@20179 491 movb $0,%dh # first head
pascal@20179 492 #else
pascal@20179 493 xorb %cl,%dh # next head
pascal@20179 494 jne bdendlp # reach head limit ?
pascal@20179 495 #endif
pascal@20179 496 # NOTE : support 256 cylinders max
pascal@20179 497 incb %ch # next cylinder
pascal@20179 498 read_first_sectors:
pascal@20179 499 bdendlp:
pascal@20179 500 jmp read_sectorslp
pascal@20179 501
pascal@20179 502 #ifdef VCPI
pascal@20179 503 pagebuf = 0x98000
pascal@20179 504 tss = gdt_abs-40
pascal@20179 505 gdt = gdt_abs-32
pascal@20179 506 gdt_null = gdt_abs-32
pascal@20179 507 gdt_vcpi = gdt_abs-24
pascal@20179 508 gdt_vcpi2 = gdt_abs-16
pascal@20179 509 gdt_vcpi3 = gdt_abs-8
pascal@20179 510 gdt_abs:
pascal@20179 511 .word 0xFFFF
pascal@20179 512 .long 0x92000000
pascal@20179 513 .byte 0xCF,0
pascal@20179 514 gdt_code:
pascal@20179 515 .word 0xFFFF
pascal@20179 516 gdt_code_base:
pascal@20179 517 .long 0x9A000000+FLAT20(0)
pascal@20179 518 .byte 0x8F,0
pascal@20179 519 gdt_tss:
pascal@20179 520 .word 0x00FF
pascal@20179 521 gdt_tss_base:
pascal@20179 522 .long 0x89000000+FLAT20(tss)
pascal@20179 523 .byte 0,0
pascal@20179 524 gdtr:
pascal@20179 525 gdt_lim:
pascal@20179 526 .word 0xFFFF
pascal@20179 527 gdt_base:
pascal@20179 528 .long FLAT20(gdt)
pascal@20179 529 sw2pm_params:
pascal@20179 530 sw2pm_cr3:
pascal@20179 531 .long pagebuf+0x1000
pascal@20179 532 sw2pm_gdtr_ptr:
pascal@20179 533 .long FLAT20(gdtr)
pascal@20179 534 sw2pm_idtr_ptr:
pascal@20179 535 .long FLAT20(idtr)
pascal@20179 536 sw2pm_ldtr:
pascal@20179 537 .word 0
pascal@20179 538 sw2pm_tr:
pascal@20179 539 SEL_TSS = gdt_tss-gdt_null
pascal@20179 540 .word SEL_TSS
pascal@20179 541 sw2pm_jumpaddr:
pascal@20179 542 .long pm_code
pascal@20179 543 SEL_CODE = gdt_code-gdt_null
pascal@20179 544 .word SEL_CODE
pascal@20179 545 idtr:
pascal@20179 546 idt_lim:
pascal@20179 547 .word 0x03FF
pascal@20179 548 idt_base:
pascal@20179 549 .long 0
pascal@20179 550 # ifndef SHUTDOWNDOS
pascal@20179 551 saved_ss_sp:
pascal@20179 552 .word stacktop-4-16-4,INITSEG
pascal@20179 553 # endif
pascal@20179 554 #endif