wok annotate BootProg/stuff/bootex.asm @ rev 25460

Update sourceforge.net web_sites with https://
author Pascal Bellard <pascal.bellard@slitaz.org>
date Wed Sep 28 08:10:35 2022 +0000 (2022-09-28)
parents 9a714ac859a3
children 81fc994927a6
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@25460 19 ;; Its maximum size can be up to 637KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on a 128MB qemu image. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@25460 51 ;; +------------------------+ A0000H - 1KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@25460 53 ;; +------------------------+ A0000H - 0.5KB ;;
pascal@25460 54 ;; | 0.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 61 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 62 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 63 ;; cs:ip = program entry point ;;
pascal@24476 64 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 65 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 66 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24945 75 ;; The command line contains no arguments. ;;
pascal@24476 76 ;; ;;
pascal@24476 77 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 78
pascal@24476 79 %define bx(label) bx+label-boot
pascal@25450 80 %define si(label) si+label-boot
pascal@25450 81 NullEntryCheck equ 1 ; +3 bytes
pascal@25450 82 ReadRetry equ 1 ; +8 bytes
pascal@25458 83 SectorOf512Bytes equ 1 ; -13 bytes
pascal@24476 84
pascal@24476 85 [BITS 16]
pascal@24476 86 [CPU 386]
pascal@24476 87
pascal@24476 88 ImageLoadSeg equ 60h
pascal@25460 89 StackSize equ 512
pascal@24476 90
pascal@24476 91 [SECTION .text]
pascal@24476 92 [ORG 0]
pascal@24476 93
pascal@24476 94 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 95 ;; Boot sector starts here ;;
pascal@24476 96 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 97
pascal@24476 98 boot:
pascal@25450 99 DriveNumber:
pascal@24476 100 jmp short start ; Windows checks for this jump
pascal@24476 101 nop
pascal@25458 102 bsOemName times 8 db " " ; 0x03 "EXFAT "
pascal@24476 103 times 53 db 0 ; 0x0B
pascal@24476 104
pascal@24476 105 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 106 ;; BPB starts here ;;
pascal@24476 107 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 108
pascal@24479 109 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 110 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 111 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 112 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 113 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 114 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 115 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 116 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 117 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 118 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 119 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 120 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 121 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 122 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 123 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 124 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 125
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;
pascal@24476 127 ;; BPB ends here ;;
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;
pascal@24476 129
pascal@24476 130 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 131 ;; Boot sector code starts here ;;
pascal@24476 132 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 133
pascal@24476 134 start:
pascal@24476 135 cld
pascal@24476 136
pascal@24476 137 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 138 ;; How much RAM is there? ;;
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 140
pascal@24476 141 int 12h ; get conventional memory size (in KBs)
pascal@24476 142 mov cx, 106h
pascal@25460 143 dec ax ; reserve 1K bytes for the code and the stack
pascal@24476 144 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 145
pascal@24476 146 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 147 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 149
pascal@24476 150 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 151 mov ss, ax
pascal@24476 152 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Copy ourselves to top of memory ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24476 158 mov si, 7C00h
pascal@24476 159 xor di, di
pascal@24476 160 mov ds, di
pascal@25450 161 push es
pascal@25450 162 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 163 rep movsw ; move 512 bytes (+ 12)
pascal@24476 164
pascal@24476 165 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 166 ;; Jump to the copy ;;
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 168
pascal@24942 169 push word main
pascal@24476 170 retf
pascal@24476 171
pascal@24476 172 main:
pascal@24476 173 push cs
pascal@24476 174 pop ds
pascal@24476 175
pascal@24476 176 xor ebx, ebx
pascal@24476 177
pascal@24476 178 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 179
pascal@24479 180 push byte ImageLoadSeg
pascal@24942 181 pop es ; cx = 0
pascal@24476 182
pascal@24476 183 RootDirReadContinue:
pascal@24476 184 call ReadCluster ; read one sector of root dir
pascal@24476 185
pascal@24476 186 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 187 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 189
pascal@25454 190 ; es:di -> root entries array
pascal@24476 191
pascal@24476 192 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 193 ;; Looks for the file/dir ProgramName ;;
pascal@24476 194 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 195 ;; Input: ES:DI -> root directory array ;;
pascal@24476 196 ;; Output: ESI = cluster number ;;
pascal@24476 197 ;; dword [bx+FileSize] file size ;;
pascal@24476 198 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 199
pascal@25450 200 CurNameSize equ 3 ; 1 byte
pascal@25450 201 StartCluster equ 14h ; 4 bytes
pascal@25450 202 FileSize equ 18h ; 8 bytes
pascal@24476 203
pascal@24476 204 FindNameCycle:
pascal@24476 205 pusha
pascal@24476 206
pascal@25450 207 %if NullEntryCheck != 0
pascal@24476 208 xor ax, ax
pascal@24476 209 or al, [es:di]
pascal@24476 210 je FindNameFailed
pascal@25450 211 %else
pascal@25450 212 movzx ax, byte [es:di]
pascal@25450 213 %endif
pascal@24476 214
pascal@24476 215 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@24476 216 jne NotFileInfo
pascal@24476 217
pascal@24942 218 mov bl, 31
pascal@24476 219 CopyInfo:
pascal@24942 220 mov al, [es:di+bx]
pascal@24942 221 mov [bx], al
pascal@24476 222 dec bx
pascal@25450 223 jnz CopyInfo ; keep BIOS boot drive number
pascal@24476 224
pascal@24476 225 NotFileInfo:
pascal@24476 226 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@24476 227 mov cx, NameLength+1
pascal@24476 228 mov si, ProgramName ; ds:si -> program name
pascal@24476 229 CheckName:
pascal@24476 230 scasw ; compare UTF-16
pascal@24476 231 lodsb ; with ASCII
pascal@24476 232 loope CheckName
pascal@24476 233 je FindNameFound ; cx = 0
pascal@24476 234 popa ; restore ax, cx, si, di
pascal@24476 235
pascal@24479 236 add di, byte 32
pascal@24945 237 cmp di, bp
pascal@24945 238 jne FindNameCycle ; next root entry
pascal@25458 239 loop RootDirReadContinue ; continue to the next root dir sector
pascal@25458 240 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 241 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 242 FindNameFailed: ; end of root directory (dir end reached)
pascal@25454 243 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 244 call Error
pascal@24476 245 db "File not found."
pascal@24476 246 FindNameFound:
pascal@24476 247 mov esi, [bx+StartCluster]
pascal@24476 248
pascal@24476 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 250 ;; Load the entire file ;;
pascal@24476 251 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 252
pascal@24476 253 push es
pascal@25458 254 %if SectorOf512Bytes == 0
pascal@24945 255 xor bp, bp
pascal@24476 256 FileReadContinue:
pascal@24476 257 shr bp, 4 ; bytes to paragraphs
pascal@24476 258 mov di, es
pascal@24476 259 add di, bp ; adjust segment for next sector
pascal@24476 260 mov es, di ; es:0 updated
pascal@25458 261 %else
pascal@25458 262 FileReadContinue:
pascal@25458 263 %endif
pascal@24943 264 call ReadCluster ; read one more sector of the boot file
pascal@25458 265 dec cx
pascal@25450 266 sub [bx+FileSize], ebp ; max FileSize is < 640KB : check low 32 bits only
pascal@25458 267 %if SectorOf512Bytes != 0
pascal@25458 268 mov bp, es
pascal@25458 269 lea bp, [bp+32]
pascal@25458 270 mov es, bp ; es:0 updated
pascal@25458 271 %endif
pascal@24476 272 ja FileReadContinue
pascal@25450 273 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25454 274 xchg ax, di
pascal@24476 275 pop bp
pascal@24476 276
pascal@24476 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 278 ;; Type detection, .COM or .EXE? ;;
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280
pascal@24476 281 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 282
pascal@24476 283 add bp, [bx+08h] ; bp = image base
pascal@24476 284 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 285
pascal@24476 286 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 287 je RelocateEXE ; yes, it's an EXE program
pascal@24476 288
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290 ;; Setup and run a .COM program ;;
pascal@24476 291 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 292 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 293 ;; cmdline=void ;;
pascal@24476 294 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 295
pascal@24525 296 mov di, 100h ; ip
pascal@24476 297 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 298 mov ss, bp
pascal@24476 299 xor sp, sp
pascal@24476 300 push bp ; cs, ds and es
pascal@24476 301 jmp short Run
pascal@24476 302
pascal@24476 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 304 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 305 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 306 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 307 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 308 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 309
pascal@24476 310 ReloCycle:
pascal@24476 311 add [di+2], bp ; item seg (abs)
pascal@24476 312 les si, [di] ; si = item ofs, es = item seg
pascal@24476 313 add [es:si], bp ; fixup
pascal@24476 314 scasw ; di += 2
pascal@24476 315 scasw ; point to next entry
pascal@24476 316
pascal@24476 317 RelocateEXE:
pascal@24942 318 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 319 jns ReloCycle
pascal@24942 320
pascal@24945 321 les si, [bx+0Eh]
pascal@24945 322 add si, bp
pascal@24945 323 mov ss, si ; ss for EXE
pascal@24945 324 mov sp, es ; sp for EXE
pascal@24476 325
pascal@24476 326 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 327 push si ; containing the PSP structure
pascal@24476 328
pascal@24476 329 add bp, [bx+16h] ; cs for EXE
pascal@24525 330 mov di, [bx+14h] ; ip for EXE
pascal@24476 331 Run:
pascal@24476 332 pop ds
pascal@24476 333 push bp
pascal@24525 334 push di
pascal@24476 335 push ds
pascal@24476 336 pop es
pascal@24942 337 mov [80h], ax ; clear cmdline
pascal@24942 338 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 339
pascal@24476 340 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 341 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 342 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 344 mov si, 16381 ; prime number 2**14-3
pascal@24476 345 mov di, 32749 ; prime number 2**15-19
pascal@24476 346 mov bp, 65521 ; prime number 2**16-15
pascal@24476 347
pascal@24476 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 349 ;; All done, transfer control to the program now ;;
pascal@24476 350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 351 retf
pascal@24476 352
pascal@25458 353 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 354 ;; Error Messaging Code ;;
pascal@25458 355 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 356
pascal@25458 357 Error:
pascal@25458 358 pop si
pascal@25458 359
pascal@25458 360 PutStr:
pascal@25458 361 mov ah, 0Eh
pascal@25458 362 mov bl, 7
pascal@25458 363 lodsb
pascal@25458 364 int 10h
pascal@25458 365 cmp al, "."
pascal@25458 366 jne PutStr
pascal@25458 367
pascal@25458 368 cbw
pascal@25458 369 int 16h ; wait for a key...
pascal@25458 370 int 19h ; bootstrap
pascal@25458 371
pascal@25458 372 Stop:
pascal@25458 373 hlt
pascal@25458 374 jmp short Stop
pascal@25458 375
pascal@24476 376 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 377 ;; Reads a exFAT cluster ;;
pascal@24476 378 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 379 ;; Input: EDX:EAX = LBA ;;
pascal@24476 380 ;; EBX = 0 ;;
pascal@24476 381 ;; CX = sector cnt ;;
pascal@24476 382 ;; ESI = cluster no ;;
pascal@24476 383 ;; ES:0 -> buffer adrs ;;
pascal@24476 384 ;; Output: EBX = 0 ;;
pascal@24476 385 ;; CX = next cnt ;;
pascal@24476 386 ;; EBP = bytes/sector;;
pascal@24476 387 ;; ES:0 -> next adrs ;;
pascal@24476 388 ;; C=0 for last sector ;;
pascal@24476 389 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 390
pascal@24476 391 ReadCluster:
pascal@24945 392 add eax, byte 1
pascal@24945 393
pascal@24476 394 inc cx ; jcxnz
pascal@24476 395 loop ReadSectorC
pascal@24476 396
pascal@24945 397 mul ebx ; edx:eax = 0
pascal@25458 398 %if SectorOf512Bytes != 0
pascal@25458 399 mov al, 128
pascal@25458 400 %else
pascal@25452 401 mov cl, -2
pascal@25450 402 add cl, [bx(bpbSectorSizeBits)]
pascal@25450 403 bts ax, cx ; eax=# of exFAT entries per sector
pascal@25458 404 %endif
pascal@24476 405 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 406 xchg eax, esi
pascal@24476 407 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 408
pascal@24525 409 imul si, dx, byte 4 ; si=entry # offset in sector
pascal@24476 410
pascal@24476 411 cdq
pascal@25452 412 add eax, [bx(bpbFatSectorStart)] ; sector # relative to exFAT
pascal@25454 413 call ReadSectorFAT ; read 1 exFAT sector, keep edx=0, set C
pascal@24476 414
pascal@24476 415 mov esi, [es:si] ; esi=next cluster #
pascal@24476 416
pascal@25450 417 mov dl, [bx(bpbSectorPerClusterBits)]
pascal@25452 418 xor ecx, ecx
pascal@25450 419 bts ecx, edx ; 10000h max (32MB cluster)
pascal@24476 420 xchg eax, edi ; get cluster #-2
pascal@24476 421 mul ecx
pascal@24476 422
pascal@24476 423 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 424 ReadSectorC:
pascal@25454 425 mov di, bx
pascal@25454 426 ReadSectorFAT:
pascal@24476 427 adc edx, ebx
pascal@24476 428
pascal@24476 429 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 430 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 431 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 432 ;; Input: EDX:EAX = LBA ;;
pascal@24476 433 ;; BX = 0 ;;
pascal@24476 434 ;; CX = sector count ;;
pascal@24476 435 ;; ES:0 -> buffer address ;;
pascal@24476 436 ;; Output: BX = 0 ;;
pascal@24476 437 ;; CX = next count ;;
pascal@24476 438 ;; EBP = bytes/sector ;;
pascal@24476 439 ;; ES:0 -> next address ;;
pascal@24476 440 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 441
pascal@25458 442 %if SectorOf512Bytes != 0
pascal@25458 443 lea ebp, [bx+512]
pascal@25458 444 %else
pascal@25458 445 lea ebp, [bx+1]
pascal@25458 446 %endif
pascal@24476 447
pascal@24476 448 pushad
pascal@24476 449
pascal@24476 450 add eax, [bx(bpbSectorStart)]
pascal@24476 451 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 452
pascal@24476 453 push edx
pascal@24476 454 push eax
pascal@24476 455 push es
pascal@24476 456 push bx
pascal@25458 457 %if SectorOf512Bytes != 0
pascal@25458 458 push byte 1 ; sector count word = 1
pascal@25458 459 %else
pascal@24476 460 push bp ; sector count word = 1
pascal@25458 461 %endif
pascal@25454 462 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24476 463 ReadSectorRetry:
pascal@24476 464 mov si, sp
pascal@24476 465 mov ah, 42h ; ah = 42h = extended read function no.
pascal@25450 466 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 467 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 468
pascal@24476 469 jnc ReadSuccess
pascal@24476 470
pascal@25450 471 %if ReadRetry != 0
pascal@24476 472 xor ax, ax
pascal@24476 473 int 13h ; reset drive (DL)
pascal@25457 474 dec bp
pascal@25458 475 %if SectorOf512Bytes != 0
pascal@25458 476 jne ReadSectorRetry ; up to 511 tries
pascal@25458 477 %else
pascal@25457 478 jpe ReadSectorRetry ; up to 3 tries
pascal@25458 479 %endif
pascal@25450 480 %endif
pascal@24476 481
pascal@24476 482 call Error
pascal@24476 483 db "Read error."
pascal@24476 484
pascal@24476 485 ReadSuccess:
pascal@25458 486 %if SectorOf512Bytes == 0
pascal@24476 487 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 488 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@25458 489 %endif
pascal@24476 490 popa ; sp += 16
pascal@24476 491 popad ; real registers
pascal@24476 492 ret
pascal@24476 493
pascal@24942 494 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 495 ;; Fill free space with zeroes ;;
pascal@24942 496 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 497
pascal@25458 498 times (512-13-($-$$)) db 0
pascal@24476 499
pascal@24476 500 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 501 ;; Name of the file to load and run ;;
pascal@24476 502 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 503
pascal@24476 504 ProgramName db "startup.bin" ; name and extension
pascal@24476 505 NameLength equ $-ProgramName
pascal@24476 506
pascal@24476 507 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 508 ;; End of the sector ID ;;
pascal@24476 509 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 510
pascal@24476 511 dw 0AA55h ; BIOS checks for this ID