wok annotate linld/stuff/src/MEMTOP.ASM @ rev 21757

tazboot: spave 40k+ for zImage
author Pascal Bellard <pascal.bellard@slitaz.org>
date Mon Jun 24 16:31:09 2019 +0200 (2019-06-24)
parents be1594cae466
children 04ffefac5707
rev   line source
pascal@19515 1 ;***************************************************************
pascal@19515 2 ;****** This file is distributed under GPL
pascal@19515 3 ;***************************************************************
pascal@19515 4 ideal
pascal@19515 5 %crefref
pascal@19515 6 %noincl
pascal@19515 7 %nomacs
pascal@19636 8 ifdef NO386
pascal@19636 9 p8086
pascal@19636 10 else
pascal@19515 11 p386
pascal@19636 12 endif
pascal@19515 13
pascal@20451 14 group DGROUP _TEXT,_BSS
pascal@19515 15 assume cs:DGROUP,ds:DGROUP
pascal@19515 16
pascal@19515 17
pascal@19515 18 segment _BSS byte public use16 'BSS'
pascal@19515 19
pascal@19515 20 saved15 dd ?
pascal@19515 21
pascal@19515 22 ends _BSS
pascal@19515 23
pascal@19515 24
pascal@19515 25 segment _TEXT byte public use16 'CODE'
pascal@19515 26
pascal@19515 27 ;***************************************************************
pascal@19515 28 ;u32 memtopz();
pascal@19515 29 ;***************************************************************
pascal@19515 30 proc _memtopz near
pascal@19515 31 ;***************************************************************
pascal@19515 32 ;u32 memtop_e801()
pascal@19515 33 ;***************************************************************
pascal@19515 34 ; proc _memtop_e801 near
pascal@19515 35
pascal@19515 36 xor cx,cx ;fix to work around buggy
pascal@19515 37 xor dx,dx ; BIOSes which dont clear/set
pascal@19515 38 stc ; carry on pass/error of
pascal@19515 39 mov ax,0E801h
pascal@19515 40 int 15h
pascal@19515 41 jc @@err
pascal@20453 42
pascal@20453 43 xchg ax,cx ;kludge to handle BIOSes
pascal@20453 44 jcxz @@use_cxdx ; which report their extended
pascal@20453 45 ; memory in AX/BX rather than
pascal@20453 46 ; CX/DX. The spec I have read
pascal@19515 47 @@use_axbx: mov dx,bx ; seems to indicate AX/BX
pascal@19882 48 xchg ax,cx ; are more reasonable anyway...
pascal@20453 49 @@use_cxdx: ;now: dx=64k units above 16m
pascal@20453 50 ; ax=1k units above 1m below 16m (max 3c00h)
pascal@20510 51 or dx,dx
pascal@19515 52 jz tokb ;dx=0 here, ax=kbs above 1m
pascal@19515 53 xor ax,ax ;ignore info on low 16M (assume full)
pascal@19515 54 ;add dx,100h ;account for low 16M
pascal@19515 55 inc dh ;account for low 16M (optimized)
pascal@19515 56 ret
pascal@19515 57 @@err:
pascal@19515 58 ; xor ax,ax
pascal@19515 59 ; cwd
pascal@19515 60 ; ret
pascal@19515 61 ; endp _memtop_e801
pascal@19515 62
pascal@19515 63
pascal@19515 64 ;***************************************************************
pascal@19515 65 ;u32 memtop_88()
pascal@19515 66 ;***************************************************************
pascal@19515 67 ; proc _memtop_88 near
pascal@19515 68
pascal@19515 69 mov ah,88h
pascal@19515 70 int 15h ;ax=kbs above 1m
pascal@20142 71 cmc ; error: cf=1 or ax=0
pascal@20142 72 sbb dx,dx
pascal@20142 73 and ax,dx ;
pascal@20142 74 jnz tokb ;happens on big mem systems
pascal@19879 75
pascal@19879 76 ;***************************************************************
pascal@19879 77 ;u32 memtop_cmos()
pascal@19879 78 ;***************************************************************
pascal@19879 79
pascal@19879 80 ;memtop_cmos:
pascal@19879 81 pushf
pascal@19879 82 call rdcmos17
pascal@19879 83 popf
pascal@19515 84 tokb:
pascal@21757 85 mov cl,10 ;multiply by 1024
pascal@21757 86 ifndef NO386
pascal@21757 87 add ah,4h ;account for 1024 low kb
pascal@21757 88 setc dl ; (optimized to death)
pascal@21757 89 shld dx,ax,cl
pascal@21757 90 shl ax,cl ; (kbytes -> bytes)
pascal@21757 91 else
pascal@19634 92 xor dx,dx
pascal@19515 93 add ah,4h ;account for 1024 low kb
pascal@19515 94 adc dx,dx ; (optimized to death)
pascal@20528 95 db 0A9h ; test ax,04B1h
pascal@20528 96 global N_LXLSH@4:near
pascal@20528 97 N_LXLSH@4:
pascal@20528 98 mov cl,4
pascal@20142 99 global N_LXLSH@:near
pascal@20142 100 N_LXLSH@:
pascal@19883 101 mov ch,0
pascal@19515 102 @@lp:
pascal@19883 103 shl ax,1
pascal@19515 104 rcl dx,1
pascal@19515 105 loop @@lp
pascal@19515 106 endif
pascal@19883 107 ret
pascal@19883 108
pascal@19515 109 ; endp _memtop_88
pascal@19515 110
pascal@19884 111 ifdef NO386
pascal@19884 112 global N_LXURSH@:near
pascal@19884 113 global N_LXURSH@4:near
pascal@19884 114 ; proc N_LXURSH@4 near
pascal@19884 115 N_LXURSH@4:
pascal@19884 116 mov cl,4
pascal@19884 117 N_LXURSH@:
pascal@19884 118 mov ch,0
pascal@19884 119 @@loop:
pascal@19884 120 shr dx,1
pascal@19884 121 rcr ax,1
pascal@19884 122 loop @@loop
pascal@19884 123 ret
pascal@19884 124
pascal@19884 125 ; endp N_LXURSH@4
pascal@19884 126
pascal@19884 127 endif
pascal@19884 128
pascal@19884 129
pascal@19515 130 ; proc _memtopz near
pascal@19515 131
pascal@19515 132 ; call _memtop_e801
pascal@19515 133 ; jnz @@ok
pascal@19515 134 ; call _memtop_88
pascal@19515 135 ; jnz @@ok
pascal@19879 136 ; jmp memtop_cmos
pascal@19515 137
pascal@20142 138 rdcmos17: cli
pascal@20142 139 mov al,18h ; read bytes 17-18 from CMOS
pascal@19515 140 call @@rdcmos
pascal@19515 141 mov ah,al
pascal@19515 142 mov al,17h
pascal@19515 143 @@rdcmos: out 70h,al
pascal@19515 144 call @@ret
pascal@19515 145 in al,71h
pascal@19515 146 @@ret:
pascal@19515 147 ret
pascal@19515 148
pascal@19515 149
pascal@19515 150 ;***************************************************************
pascal@19515 151 ;u32 memtop();
pascal@19515 152 ;***************************************************************
pascal@19515 153 global _memtop:near
pascal@19515 154 _memtop:
pascal@19515 155 call _memtopz
pascal@19515 156 mov cx,40h ; min 4m
pascal@19515 157 ; If reported mem is ridiculously low, presume
pascal@19515 158 ; we had trouble detecting memory size
pascal@19515 159 cmp dx,cx
pascal@19515 160 jb @@set
pascal@20451 161 extrn _topmem:dword
pascal@20528 162 mov cx,[word _topmem+2]
pascal@20528 163 inc cx ; jcxnz
pascal@20528 164 loop @@topmemset
pascal@20528 165 mov ch,10h ; default = max 256m
pascal@20528 166 @@topmemset:
pascal@19515 167 ; Kernel can have trouble with initrd at very high addr:
pascal@19515 168 ; limit mem top to 256m
pascal@19515 169 cmp dh,ch
pascal@19515 170 jb @@done
pascal@19515 171 @@set:
pascal@19515 172 xchg ax,cx
pascal@19515 173 cwd
pascal@19515 174 xchg ax,dx
pascal@19515 175 @@done:
pascal@19515 176 ; Round down to page boundary.
pascal@19515 177 ; Or else initrd's tail may end up in last, partial page.
pascal@19515 178 ; Kernel will refuse to use such initrd.
pascal@19515 179 and ax,0f000h
pascal@19515 180 ;@@ok:
pascal@19515 181 ret
pascal@19515 182
pascal@19515 183 endp _memtopz
pascal@19515 184
pascal@19515 185 ;***************************************************************
pascal@19515 186 ;void hook_int15_88();
pascal@19515 187 ;***************************************************************
pascal@19515 188 global _hook_int15_88:near
pascal@19515 189 proc _hook_int15_88 near
pascal@19515 190
pascal@19515 191 ifndef xmm_hook
pascal@19515 192 mov ax,4300h
pascal@19515 193 int 2fh
pascal@19571 194 cmp al,80h ; 80h = XMS driver installed
pascal@19515 195 je @@skip
pascal@19515 196 endif
pascal@19883 197 xor bx,bx
pascal@19883 198 mov es,bx
pascal@19571 199 ifndef NO386
pascal@19876 200 push cs
pascal@19876 201 push offset int15_88
pascal@19876 202 pop eax
pascal@19883 203 xchg eax,[es:bx+15*4]
pascal@19515 204 mov [saved15],eax
pascal@19515 205 else
pascal@19876 206 mov ax,offset int15_88
pascal@19883 207 xchg ax,[es:bx+15*4]
pascal@19515 208 mov [word saved15],ax
pascal@19876 209 mov ax,cs
pascal@19883 210 xchg ax,[es:bx+15*4+2]
pascal@19515 211 mov [word saved15+2],ax
pascal@19515 212 endif
pascal@21757 213 ;push ds
pascal@21757 214 ;pop es
pascal@19515 215 @@skip:
pascal@19515 216 ret
pascal@19515 217 int15_88:
pascal@19515 218 cmp ah,88h
pascal@19515 219 je @@do88
pascal@19515 220 jmp [saved15]
pascal@19515 221 @@do88:
pascal@19515 222 pushf
pascal@21302 223 call [saved15]
pascal@20510 224 or ax,ax
pascal@19515 225 jnz @@iret
pascal@19515 226
pascal@19515 227 ;****** Read extended mem size (CMOS bytes 17h,18h (lo,hi))
pascal@19515 228 call rdcmos17
pascal@19515 229 @@iret:
pascal@19515 230 iret
pascal@19515 231
pascal@19515 232 endp _hook_int15_88
pascal@19515 233
pascal@19515 234 ends _TEXT
pascal@19515 235
pascal@19515 236 end
pascal@19515 237
pascal@19515 238 ;###### END OF FILE ############################################