wok annotate ipxe/stuff/lkrnprefix.S @ rev 19275

Check manpages... from start to beaver.
author Aleksej Bobylev <al.bobylev@gmail.com>
date Tue Jul 05 15:34:01 2016 +0300 (2016-07-05)
parents 6aed6fc5819d
children
rev   line source
pascal@15368 1 /*
pascal@15368 2 Copyright (C) 2000, Entity Cyber, Inc.
pascal@15368 3
pascal@15368 4 Authors: Gary Byers (gb@thinguin.org)
pascal@15368 5 Marty Connor (mdc@thinguin.org)
pascal@15368 6
pascal@15368 7 This software may be used and distributed according to the terms
pascal@15368 8 of the GNU Public License (GPL), incorporated herein by reference.
pascal@15368 9
pascal@15368 10 Description:
pascal@15368 11
pascal@15368 12 This is just a little bit of code and data that can get prepended
pascal@15368 13 to a ROM image in order to allow bootloaders to load the result
pascal@15368 14 as if it were a Linux kernel image.
pascal@15368 15
pascal@15368 16 A real Linux kernel image consists of a one-sector boot loader
pascal@15368 17 (to load the image from a floppy disk), followed a few sectors
pascal@15368 18 of setup code, followed by the kernel code itself. There's
pascal@15368 19 a table in the first sector (starting at offset 497) that indicates
pascal@15368 20 how many sectors of setup code follow the first sector and which
pascal@15368 21 contains some other parameters that aren't interesting in this
pascal@15368 22 case.
pascal@15368 23
pascal@15368 24 We don't require much in the way of setup code. Historically, the
pascal@15368 25 Linux kernel required at least 4 sectors of setup code.
pascal@15368 26 Therefore, at least 4 sectors must be present even though we don't
pascal@15368 27 use them.
pascal@15368 28
pascal@15368 29 */
pascal@15368 30
pascal@15368 31 FILE_LICENCE ( GPL_ANY )
pascal@15368 32
pascal@15368 33 #define SETUPSECS 4 /* Minimal nr of setup-sectors */
pascal@15368 34 #define PREFIXSIZE ((SETUPSECS+1)*512)
pascal@15368 35 #define PREFIXPGH (PREFIXSIZE / 16 )
pascal@15368 36 #define BOOTSEG 0x07C0 /* original address of boot-sector */
pascal@15368 37 #define INITSEG 0x9000 /* we move boot here - out of the way */
pascal@15368 38 #define SETUPSEG 0x9020 /* setup starts here */
pascal@15368 39 #define SYSSEG 0x1000 /* system loaded at 0x10000 (65536). */
pascal@15368 40
pascal@15368 41 .text
pascal@15368 42 .code16
pascal@15368 43 .arch i386
pascal@15368 44 .org 0
pascal@15368 45 .section ".prefix", "ax", @progbits
pascal@15368 46 .globl _lkrn_start
pascal@15368 47 _lkrn_start:
pascal@15368 48
pascal@15368 49 bootsector:
pascal@15368 50 _start:
pascal@15368 51
pascal@15368 52 /* some extra features */
pascal@15368 53 #define EXE_SUPPORT real mode dos .exe file support
pascal@15368 54
pascal@15368 55 #define EXEADRS(x) (x+0xE0)
pascal@15368 56
pascal@15368 57 /* some contraints to reduce the size */
pascal@15368 58 //#define FLOPPY_1440K_ONLY 1.44M floppies support only
pascal@15368 59
pascal@15368 60 #ifdef EXE_SUPPORT
pascal@15368 61 /* Initial temporary stack size */
pascal@15368 62 #define EXE_STACK_SIZE 0x400
pascal@15368 63
pascal@15368 64 /* Temporary decompression area (avoid DOS high memory area) */
pascal@15368 65 #define EXE_DECOMPRESS_ADDRESS 0x110000
pascal@15368 66
pascal@15368 67 /* Fields within the Program Segment Prefix */
pascal@15368 68 #define PSP_CMDLINE_LEN 0x80
pascal@15368 69 #define PSP_CMDLINE_START 0x81
pascal@15368 70
pascal@15368 71 #define HEADER_SIZE 0x20
pascal@15368 72
pascal@15368 73 signature:
pascal@15368 74 decw %bp // Magic number: MZ
pascal@15368 75 popw %dx
pascal@15368 76 jmp start // Bytes on last page of file
pascal@15368 77 blocks:
pascal@15368 78 .word 0 // Pages in file
pascal@15368 79 .section ".zinfo.fixup", "a", @progbits /* Compressor fixups */
pascal@15368 80 .ascii "ADDW"
pascal@15368 81 .long blocks
pascal@15368 82 .long 512
pascal@15368 83 .long 0
pascal@15368 84 .previous
pascal@15368 85 .word 0 // Relocations
pascal@15368 86 .word ( HEADER_SIZE / 16 ) // Size of header in paragraphs
pascal@15368 87 .word ( EXE_STACK_SIZE / 16 ) // Minimum extra paragraphs needed
pascal@15368 88 .word ( EXE_STACK_SIZE / 16 ) // Maximum extra paragraphs needed
pascal@15368 89 init_ss:
pascal@15368 90 .word -( ( _exe_start - signature ) / 16 ) // Initial (relative) SS value
pascal@15368 91 .section ".zinfo.fixup", "a", @progbits /* Compressor fixups */
pascal@15368 92 .ascii "ADDW"
pascal@15368 93 .long init_ss
pascal@15368 94 .long 16
pascal@15368 95 .long 0
pascal@15368 96 .previous
pascal@15368 97 .word EXE_STACK_SIZE // Initial SP value
pascal@15368 98 .word 0 // Checksum
pascal@15368 99 .word _exe_start // Initial IP value
pascal@15368 100 /* Initial code segment (relative to start of executable) */
pascal@15368 101 .word -( HEADER_SIZE / 16 ) // Initial (relative) CS value
pascal@15368 102 // .word 0x001C // File address of relocation table
pascal@15368 103 // .word 0,0,0 // Overlay number
pascal@17473 104 .ascii "(SliTaz)"
pascal@15368 105
pascal@15368 106 start:
pascal@15368 107 pushw %dx
pascal@15368 108 #endif
pascal@15368 109 cld # assume nothing
pascal@15368 110 stacktop = 0x9E00 # in 0x8000 .. 0xA000
pascal@15368 111 zeroed = 12 # zeroed registers
pascal@15368 112 movw $stacktop-12-zeroed, %di # stacktop is an arbitrary value >=
pascal@15368 113 # length of bootsect + length of
pascal@15368 114 # setup + room for stack;
pascal@15368 115 # 12 is disk parm size.
pascal@15368 116 pushw $INITSEG
pascal@15368 117 popw %ss # %ss contain INITSEG
pascal@15368 118 movw %di, %sp # put stack at INITSEG:stacktop-...
pascal@15368 119
pascal@15368 120 # Many BIOS's default disk parameter tables will not recognize
pascal@15368 121 # multi-sector reads beyond the maximum sector number specified
pascal@15368 122 # in the default diskette parameter tables - this may mean 7
pascal@15368 123 # sectors in some cases.
pascal@15368 124 #
pascal@15368 125 # Since single sector reads are slow and out of the question,
pascal@15368 126 # we must take care of this by creating new parameter tables
pascal@15368 127 # (for the first disk) in RAM. We can set the maximum sector
pascal@15368 128 # count to 36 - the most we will encounter on an ED 2.88.
pascal@15368 129 #
pascal@15368 130 # High doesn't hurt. Low does. Let's use the max: 63
pascal@15368 131
pascal@15368 132 pushw %ss
pascal@15368 133 popw %es # %es = %ss = INITSEG
pascal@15368 134 xorw %ax, %ax # %ax = 0
pascal@15472 135 #ifdef EXE_SUPPORT
pascal@15472 136 cwd # %dx = 0
pascal@15472 137 #endif
pascal@15368 138 movw $zeroed/2, %cx # clear gdt + offset, %ds, limits
pascal@15368 139 rep # don't worry about cld
pascal@15368 140 stosw # already done above
pascal@15368 141 popw %bx # offset = 0
pascal@15368 142 popw %ds # %ds = 0
pascal@15368 143 popw %fs # %fs = 0
pascal@15368 144
pascal@15368 145 movb setup_sects+0x7C00, %al # read bootsector + setup (%ds = 0)
pascal@15368 146 incw %ax
pascal@15368 147
pascal@15368 148 ldsw 0x78(%bx), %si # %ds:%bx+0x78 is parameter table address
pascal@15368 149 pushw %es
pascal@15368 150 pushw %di
pascal@15368 151 movb $6, %cl # copy 12 bytes
pascal@15368 152 rep # don't worry about cld
pascal@15368 153 movsw # already done above
pascal@15368 154 pushw %ss
pascal@15368 155 popw %ds # now %ds = %es = %ss = INITSEG
pascal@15368 156 popl %fs:0x78(%bx) # update parameter table address
pascal@15368 157 movb $63, 0x4-12(%di) # patch sector count, %di = stacktop
pascal@15368 158 cli
pascal@15368 159
pascal@15368 160 xchg %ax, %di # sector count
pascal@15368 161 popw %ax # limits = 0
pascal@15368 162 incw %cx # cylinder 0, sector 1, clear Z
pascal@15368 163 call read_first_sectors # read setup
pascal@15368 164
pascal@15368 165 # This routine loads the system at address LOADSEG, making sure
pascal@15368 166 # no 64kB boundaries are crossed. We try to load it as fast as
pascal@15368 167 # possible, loading whole tracks whenever we can.
pascal@15368 168
pascal@15368 169 popw %bx # clear %bx
pascal@15368 170 movw syssize, %di
pascal@15368 171 addw $(512/16)-1, %di
pascal@15368 172 shrw $9-4, %di
pascal@15368 173 movw $SYSSEG, %cx
pascal@15368 174 call read_sectorsCX
pascal@15368 175
pascal@15368 176 # This procedure turns off the floppy drive motor, so
pascal@15368 177 # that we enter the kernel in a known state, and
pascal@15368 178 # don't have to worry about it later.
pascal@15368 179
pascal@15368 180 kill_motor:
pascal@15368 181 xchgw %ax, %di # reset FDC (%di < 128)
pascal@15368 182 int $0x13
pascal@15368 183
pascal@15368 184 # After that (everything loaded), we jump to the setup-routine
pascal@15368 185 # loaded directly after the bootblock:
pascal@15368 186 # Segments are as follows: %ds = %ss = INITSEG
pascal@15368 187
pascal@15368 188 ljmp $SETUPSEG, $0
pascal@15368 189
pascal@15368 190 #ifdef EXE_SUPPORT
pascal@15368 191 dosexit:
pascal@15368 192 movw $0x4c00, %ax
pascal@15368 193 int $0x21
pascal@15368 194
pascal@15368 195 _exe_start:
pascal@15368 196 pushw $dosexit
pascal@15368 197 movw $EXEADRS(need386), %si
pascal@15368 198 pushfw // save flags
pascal@15368 199 // bits 15 14 13 12 11 10 9 8 7 6 5 4 3 2 1 0
pascal@15368 200 // flags 0 NT IOPL OF DF IF TF SF ZF 0 AF 0 PF 1 CF
pascal@15368 201 movb $0x10, %ah // DF = IF = TF = 0
pascal@15368 202 pushw %ax
pascal@15368 203 popfw // < 286 : flags[12..15] are forced 1
pascal@15368 204 pushfw // = 286 : flags[12..15] are forced 0
pascal@15368 205 popw %cx // > 286 : only flags[15] is forced 0
pascal@15368 206 popfw // restore flags
pascal@15485 207 cmpb %ah, %ch // test Fx and 0x cases
pascal@15485 208 js puts // S= not 386+
pascal@15368 209 // smsww %ax
pascal@15368 210 // andb $1, %al
pascal@15368 211 // jne puts
pascal@15368 212
pascal@15368 213 /* Terminate command line with a NUL */
pascal@15368 214 movzbw PSP_CMDLINE_LEN, %si
pascal@15368 215 movb $0, PSP_CMDLINE_START(%si)
pascal@15368 216 cmpb $'?', PSP_CMDLINE_START-1(%si)
pascal@15368 217 je help
pascal@15368 218 pushw %si
pascal@15368 219
pascal@15368 220 /* Install iPXE. Use a fixed temporary decompression area to
pascal@15368 221 * avoid trashing the DOS high memory area.
pascal@15368 222 */
pascal@15368 223 call alloc_basemem
pascal@15368 224 movl $EXE_DECOMPRESS_ADDRESS, %edi
pascal@15368 225 stc
pascal@15368 226 sbbl %ebp, %ebp /* Allow arbitrary relocation */
pascal@15368 227 xorl %esi, %esi
pascal@15368 228 call install_prealloc
pascal@15368 229
pascal@15368 230 xorl %ebp, %ebp
pascal@15368 231 xorl %ecx, %ecx
pascal@15368 232
pascal@15368 233 /* Calculate command line physical address */
pascal@15368 234 xorl %edx, %edx
pascal@15368 235 movw %ds, %dx
pascal@15368 236 shll $4, %edx
pascal@15368 237 popw %si
pascal@15368 238 orw %si, %si
pascal@15368 239 jne gotarg
pascal@15368 240 movw $EXEADRS(default_config), %bp
pascal@15368 241 addl %edx, %ebp
pascal@15368 242 movw $0xA00-default_config, %cx
pascal@15368 243 gotarg:
pascal@15368 244 addl $PSP_CMDLINE_START, %edx
pascal@15368 245
pascal@15368 246 jmp start_ipxe
pascal@15368 247
pascal@15368 248 help:
pascal@15368 249 movw $EXEADRS(helpmsg), %si
pascal@15368 250 puts:
pascal@15368 251 lodsb
pascal@15368 252 orb %al, %al
pascal@15368 253 je exit
pascal@15368 254 call putc
pascal@15368 255 jmp puts
pascal@15368 256 #endif
pascal@15368 257
pascal@15368 258 putcdot:
pascal@15368 259 movb $0x2E, %al
pascal@15368 260 putc:
pascal@15368 261 movb $0xE, %ah
pascal@15368 262 movw $7, %bx
pascal@15368 263 int $0x10
pascal@15368 264 exit:
pascal@15368 265 ret
pascal@15368 266
pascal@15368 267
pascal@15368 268 # read_sectors reads %di sectors into %es:0 buffer.
pascal@15368 269 # %es:0 is updated to the next memory location.
pascal@15368 270 # First, sectors are read sector by sector until
pascal@15368 271 # sector per track count is known. Then they are
pascal@15368 272 # read track by track.
pascal@15368 273 # Assume no error on first track.
pascal@15368 274
pascal@15368 275 #ifdef FLOPPY_1440K_ONLY
pascal@15368 276 #define FLOPPY_HEADS 2 /* 2 heads */
pascal@15368 277 #define FLOPPY_SECTORS 18 /* 18 sectors */
pascal@15368 278 #else
pascal@15368 279 #define FLOPPY_HEADS 2 /* 2 heads minimum */
pascal@15368 280 #define FLOPPY_SECTORS 9 /* 9 sectors minimum */
pascal@15368 281 #endif
pascal@15368 282
pascal@15368 283 check_limits:
pascal@15368 284 #ifndef FLOPPY_1440K_ONLY
pascal@15368 285 popw %dx
pascal@15368 286 #ifdef FLOPPY_SECTORS
pascal@15368 287 cmpb $FLOPPY_SECTORS+1, %cl # minimum sector count
pascal@15368 288 jb check_head
pascal@15368 289 #endif
pascal@15368 290 cmpb %al, %cl # max sector known ?
pascal@15368 291 ja next_head # no -> store it
pascal@15368 292 check_head:
pascal@15368 293 #ifdef FLOPPY_HEADS
pascal@15368 294 cmpb $FLOPPY_HEADS, %dh # 2 heads minimum
pascal@15368 295 jb check_cylinder
pascal@15368 296 #endif
pascal@15368 297 cmpb %ah, %dh # max head known ?
pascal@15368 298 ja next_cylinder # no -> store it
pascal@15368 299 check_cylinder:
pascal@15368 300 #endif
pascal@15368 301 pushaw
pascal@15368 302 #ifndef FLOPPY_1440K_ONLY
pascal@15368 303 cbw # %ah = 0
pascal@15368 304 #endif
pascal@15368 305 int $0x13 # reset controler
pascal@15368 306 popaw
pascal@15368 307 movb $1, %al # sector by sector...
pascal@15368 308 read_sectorslp:
pascal@15368 309 pushw %dx # some bios break dx...
pascal@15368 310 #ifndef FLOPPY_1440K_ONLY
pascal@15368 311 pushw %ax # limits
pascal@15368 312 subb %cl, %al # sectors remaining in track
pascal@15368 313 ja tolastsect
pascal@15368 314 movb $1, %al # 1 sector mini
pascal@15368 315 tolastsect:
pascal@15368 316 #else
pascal@15368 317 mov $FLOPPY_SECTORS+1, %al
pascal@15368 318 subb %cl, %al # sectors remaining in track
pascal@15368 319 #endif
pascal@15368 320 cbw
pascal@15368 321 cmpw %di, %ax
pascal@15368 322 jb more1trk
pascal@15368 323 movw %di, %ax # sectors to read
pascal@15368 324 more1trk:
pascal@15368 325 pushw %ax # save context
pascal@15368 326 movb $2, %ah # cmd: read chs
pascal@15368 327 int $0x13
pascal@15368 328 #ifndef FLOPPY_1440K_ONLY
pascal@15368 329 popw %dx # save %ax
pascal@15368 330 popw %ax # limits
pascal@15368 331 #else
pascal@15368 332 popw %ax # restore context
pascal@15368 333 popw %dx
pascal@15368 334 #endif
pascal@15368 335 jc check_limits
pascal@15368 336 #ifndef FLOPPY_1440K_ONLY
pascal@15368 337 xchgw %ax, %bp
pascal@15368 338 addw %dx,%cx # next sector
pascal@15368 339 movw %cx, %gs
pascal@15368 340 movw %es, %cx
pascal@15368 341 pushw %dx
pascal@15368 342 shlw $5, %dx
pascal@15368 343 addw %dx, %cx
pascal@15368 344 popw %dx
pascal@15368 345 subw %dx,%di # update sector counter
pascal@15368 346 popw %dx
pascal@15368 347 read_sectorsCX:
pascal@15368 348 movw %cx, %es # next location
pascal@15368 349 jz putcdot
pascal@15368 350 #else
pascal@15368 351 addw %ax,%cx # next sector
pascal@15368 352 movw %cx, %gs
pascal@15368 353 movw %es, %cx
pascal@15368 354 pushw %ax
pascal@15368 355 shlw $5, %ax
pascal@15368 356 addw %ax, %cx
pascal@15368 357 popw %ax
pascal@15368 358 subw %ax,%di # update sector counter
pascal@15368 359 read_sectorsCX:
pascal@15368 360 movw %cx, %es # next location
pascal@15368 361 jz putcdot
pascal@15368 362 #endif
pascal@15368 363 read_sectors:
pascal@15368 364 movw %gs, %cx
pascal@15368 365 #ifndef FLOPPY_1440K_ONLY
pascal@15368 366 # al is last sector+1
pascal@15368 367 # ah is last cylinder+1
pascal@15368 368 xchgw %ax, %bp
pascal@15368 369 #endif
pascal@15368 370 #ifndef FLOPPY_1440K_ONLY
pascal@15368 371 cmpb %al,%cl # reach sector limit ?
pascal@15368 372 jne bdendlp
pascal@15368 373 next_head:
pascal@15368 374 movb %cl,%al
pascal@15368 375 #else
pascal@15368 376 cmpb $FLOPPY_SECTORS+1,%cl # reach sector limit ?
pascal@15368 377 jne bdendlp
pascal@15368 378 #endif
pascal@15368 379 incb %dh # next head
pascal@15368 380 movb $1,%cl # first sector
pascal@15368 381 #ifndef FLOPPY_1440K_ONLY
pascal@15368 382 cmpb %ah, %dh # reach head limit ?
pascal@15368 383 jne bdendlp
pascal@15368 384 next_cylinder:
pascal@15368 385 movb %dh,%ah
pascal@15368 386 #else
pascal@15368 387 cmpb %cl,%dh # reach head limit ?
pascal@15368 388 je bdendlp
pascal@15368 389 #endif
pascal@15368 390 # NOTE : support 256 cylinders max
pascal@15368 391 incb %ch # next cylinder
pascal@18880 392 movb $0,%dh # first head
pascal@15368 393 read_first_sectors:
pascal@15368 394 bdendlp:
pascal@15368 395 jmp read_sectorslp
pascal@15368 396
pascal@15368 397 #ifdef EXE_SUPPORT
pascal@15368 398 need386:
pascal@15368 399 .ascii "No 386+."
pascal@15368 400 .byte 13,10
pascal@15368 401 .byte 0
pascal@15368 402 helpmsg:
pascal@15368 403 .ascii "No help available."
pascal@15368 404 .byte 13,10
pascal@15368 405 .byte 0
pascal@15368 406 #endif
pascal@15368 407
pascal@15368 408 /*
pascal@15368 409 The following header is documented in the Linux source code at
pascal@15368 410 Documentation/x86/boot.txt
pascal@15368 411 */
pascal@15368 412 .org 497
pascal@15368 413 setup_sects:
pascal@15368 414 .byte SETUPSECS
pascal@15368 415 root_flags:
pascal@15368 416 .word 0
pascal@15368 417 syssize:
pascal@15368 418 .long -PREFIXPGH
pascal@15368 419
pascal@15368 420 .section ".zinfo.fixup", "a", @progbits /* Compressor fixups */
pascal@15368 421 .ascii "ADDL"
pascal@15368 422 .long syssize
pascal@15368 423 .long 16
pascal@15368 424 .long 0
pascal@15368 425 .previous
pascal@15368 426
pascal@15368 427 ram_size:
pascal@15368 428 .word 0
pascal@15368 429 vid_mode:
pascal@15368 430 .word 0
pascal@15368 431 root_dev:
pascal@15368 432 .word 0
pascal@15368 433 boot_flag:
pascal@15368 434 .word 0xAA55
pascal@15368 435 jump:
pascal@15368 436 /* Manually specify a two-byte jmp instruction here rather
pascal@15368 437 * than leaving it up to the assembler. */
pascal@15368 438 .byte 0xeb
pascal@15368 439 .byte setup_code - header
pascal@15368 440 header:
pascal@15368 441 .byte 'H', 'd', 'r', 'S'
pascal@15368 442 version:
pascal@15368 443 .word 0x0207 /* 2.07 */
pascal@15368 444 realmode_swtch:
pascal@15368 445 .long 0
pascal@15368 446 start_sys:
pascal@15368 447 .word 0
pascal@15368 448 kernel_version:
pascal@15368 449 .word 0
pascal@15368 450 type_of_loader:
pascal@15368 451 .byte 0
pascal@15368 452 loadflags:
pascal@15368 453 .byte 0
pascal@15368 454 setup_move_size:
pascal@15368 455 .word 0
pascal@15368 456 code32_start:
pascal@15368 457 .long SYSSEG*16
pascal@15368 458 ramdisk_image:
pascal@15368 459 .long 0
pascal@15368 460 ramdisk_size:
pascal@15368 461 .long 0
pascal@15368 462 bootsect_kludge:
pascal@15368 463 .long 0
pascal@15368 464 heap_end_ptr:
pascal@15368 465 .word 0
pascal@15368 466 pad1:
pascal@15368 467 .word 0
pascal@15368 468 cmd_line_ptr:
pascal@15368 469 .long 0
pascal@15368 470 initrd_addr_max:
pascal@15368 471 /* We don't use an initrd but some bootloaders (e.g. SYSLINUX) have
pascal@15368 472 * been known to require this field. Set the value to 2 GB. This
pascal@15368 473 * value is also used by the Linux kernel. */
pascal@15368 474 .long 0x7fffffff
pascal@15368 475 kernel_alignment:
pascal@15368 476 .long 0
pascal@15368 477 relocatable_kernel:
pascal@15368 478 .byte 0
pascal@15368 479 pad2:
pascal@15368 480 .byte 0, 0, 0
pascal@15368 481 cmdline_size:
pascal@15368 482 .long 0x7ff
pascal@15368 483 hardware_subarch:
pascal@15368 484 .long 0
pascal@15368 485 hardware_subarch_data:
pascal@15368 486 .byte 0, 0, 0, 0, 0, 0, 0, 0
pascal@15368 487
pascal@15368 488 /*
pascal@15368 489 We don't need to do too much setup.
pascal@15368 490
pascal@15368 491 This code gets loaded at SETUPSEG:0. It wants to start
pascal@15368 492 executing the image that's loaded at SYSSEG:0 and
pascal@15368 493 whose entry point is SYSSEG:0.
pascal@15368 494 */
pascal@15368 495 setup_code:
pascal@15368 496 movl ramdisk_image, %eax
pascal@15368 497 orl %eax, %eax
pascal@15368 498 jnz setup_done
pascal@15368 499
pascal@15368 500 movw $default_config, %di
pascal@15368 501 movw $-1, %bx
pascal@15368 502
pascal@15368 503 movw $9, %cx
pascal@15368 504 1:
pascal@15368 505 pushw %ax
pascal@15368 506 loop 1b
pascal@15368 507 pushw $0x9310
pascal@15368 508 pushw %ax
pascal@15368 509 pushw %bx
pascal@15368 510 pushw %ax
pascal@15368 511 pushw $0x9300+(INITSEG>>12)
pascal@15368 512 pushw %di
pascal@15368 513 pushw %bx
pascal@15368 514 movb $8, %cl
pascal@15368 515 1:
pascal@15368 516 pushw %ax
pascal@15368 517 loop 1b
pascal@15368 518 1:
pascal@15368 519 incw %bx
pascal@15368 520 cmpb %al, (%bx,%di)
pascal@15368 521 jne 1b
pascal@15368 522 movw %bx, ramdisk_size
pascal@15368 523 movb $0x10, ramdisk_image+2
pascal@15368 524
pascal@15368 525 pushw %ss
pascal@15368 526 popw %es
pascal@15368 527 movw %sp, %si
pascal@15368 528 movb $0x87, %ah
pascal@15368 529 movw $(run_ipxe-default_config)/2+1, %cx
pascal@15368 530 int $0x15
pascal@15368 531
pascal@15368 532 setup_done:
pascal@15368 533 /* We expect to be contiguous in memory once loaded. The Linux image
pascal@15368 534 * boot process requires that setup code is loaded separately from
pascal@15368 535 * "non-real code". Since we don't need any information that's left
pascal@15368 536 * in the prefix, it doesn't matter: we just have to ensure that
pascal@15368 537 * %cs:0000 is where the start of the image *would* be.
pascal@15368 538 */
pascal@15368 539 ljmp $(SYSSEG-(PREFIXSIZE/16)), $run_ipxe
pascal@15368 540
pascal@15368 541 default_config:
pascal@15368 542
pascal@15368 543 .org PREFIXSIZE
pascal@15368 544 /*
pascal@15368 545 We're now at the beginning of the kernel proper.
pascal@15368 546 */
pascal@15368 547 run_ipxe:
pascal@15368 548 /* Set up stack just below 0x7c00 and clear direction flag */
pascal@15368 549 xorw %ax, %ax
pascal@15368 550 movw %ax, %ss
pascal@15368 551 movw $0x7c00, %sp
pascal@15368 552 cld
pascal@15368 553
pascal@15368 554 /* Retrieve command-line pointer */
pascal@15368 555 movl %ds:cmd_line_ptr, %edx
pascal@15368 556 testl %edx, %edx
pascal@15368 557 jz no_cmd_line
pascal@15368 558
pascal@15368 559 /* Set up %es:%di to point to command line */
pascal@15368 560 movl %edx, %edi
pascal@15368 561 andl $0xf, %edi
pascal@15368 562 rorl $4, %edx
pascal@15368 563 movw %dx, %es
pascal@15368 564
pascal@15368 565 /* Find length of command line */
pascal@15368 566 pushw %di
pascal@15368 567 movw $0xffff, %cx
pascal@15368 568 repnz scasb
pascal@15368 569 notw %cx
pascal@15368 570 popw %si
pascal@15368 571
pascal@15368 572 /* Make space for command line on stack */
pascal@15368 573 movw %sp, %di
pascal@15368 574 subw %cx, %di
pascal@15368 575 andw $~0xf, %di
pascal@15368 576 movw %di, %sp
pascal@15368 577
pascal@15368 578 /* Copy command line to stack */
pascal@15368 579 pushw %ds
pascal@15368 580 pushw %es
pascal@15368 581 popw %ds
pascal@15368 582 pushw %ss
pascal@15368 583 popw %es
pascal@15368 584 rep movsb
pascal@15368 585 popw %ds
pascal@15368 586
pascal@15368 587 /* Store new command-line pointer */
pascal@15368 588 movzwl %sp, %edx
pascal@15368 589 no_cmd_line:
pascal@15368 590
pascal@15368 591 /* Calculate maximum relocation address */
pascal@15368 592 movl ramdisk_image, %ebp
pascal@15368 593 testl %ebp, %ebp
pascal@15368 594 jnz 1f
pascal@15368 595 decl %ebp /* Allow arbitrary relocation if no initrd */
pascal@15368 596 1:
pascal@15368 597
pascal@15368 598 /* Install iPXE */
pascal@15368 599 call alloc_basemem
pascal@15368 600 xorl %esi, %esi
pascal@15368 601 xorl %edi, %edi
pascal@15368 602 call install_prealloc
pascal@15368 603
pascal@15368 604 /* Retrieve initrd pointer and size */
pascal@15368 605 movl ramdisk_image, %ebp
pascal@15368 606 movl ramdisk_size, %ecx
pascal@15368 607
pascal@15368 608 start_ipxe:
pascal@15368 609 /* Set up real-mode stack */
pascal@15368 610 movw %bx, %ss
pascal@15368 611 movw $_estack16, %sp
pascal@15368 612
pascal@15368 613 /* Jump to .text16 segment */
pascal@15368 614 pushw %ax
pascal@15368 615 pushw $1f
pascal@15368 616 lret
pascal@15368 617 .section ".text16", "awx", @progbits
pascal@15368 618 1:
pascal@15368 619 /* Set up %ds for access to .data16 */
pascal@15368 620 movw %bx, %ds
pascal@15368 621
pascal@15368 622 /* Store command-line pointer */
pascal@15368 623 movl %edx, cmdline_phys
pascal@15368 624
pascal@15368 625 /* Store initrd pointer and size */
pascal@15368 626 movl %ebp, initrd_phys
pascal@15368 627 movl %ecx, initrd_len
pascal@15368 628
pascal@15368 629 /* Run iPXE */
pascal@15368 630 pushl $main
pascal@15368 631 pushw %cs
pascal@15368 632 call prot_call
pascal@15368 633 popl %ecx /* discard */
pascal@15368 634
pascal@15368 635 /* Uninstall iPXE */
pascal@15368 636 call uninstall
pascal@15368 637
pascal@15368 638 /* Boot next device */
pascal@15368 639 int $0x18