wok view linld/stuff/src/VCPI.ASM @ rev 20454
Up zstd (1.3.6)
| author | Pascal Bellard <pascal.bellard@slitaz.org> |
|---|---|
| date | Sat Oct 06 15:17:20 2018 +0200 (2018-10-06) |
| parents | a0df590cdf14 |
| children | 2e46d946d7a8 |
line source
1 ;***************************************************************
2 ;****** This file is distributed under GPL
3 ;***************************************************************
4 ;VDPI init:
5 ;Call char* prepare_vcpi(void *pagebuf) first to
6 ;initialize paging tables needed for vm86.
7 ;pagebuf needs to be 8k+4 bytes. Returns ptr to 1st unused byte.
8 ;Then call int get_vcpi_interface(). Returns 1 if ok, 0 if bad.
9 ;
10 ;VCPI use:
11 ;u32* malloc_vcpi(u32 size) - source in HIMEM.CPP
12 ; Returns ptr to mallocated zero-terminated list of 4k page addrs
13 ; Addresses are sorted in ascending order
14 ; Never fails (will die if not enough mem)
15 ;void read2vcpi(int fd, u32* vp, u32 size,
16 ;void* xfer_buf, u16 xfer_size) - source in HIMEM.CPP
17 ; Reads opened fd data into malloc_vcpi'ed memory
18 ; Dies if file isn't exactly 'size' bytes long
19 ; Needs intermediate buffer of exactly Nx4k bytes
20 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs)
21 ; copies 4k from conventional memory to VCPI
22 ;void _vm2rm()
23 ; switches you from vm86 to plain real mode
26 ideal
27 %crefref
28 %noincl
29 %nomacs
30 p386
32 ;****** Stuff for declaring descriptors
33 struc descr
34 limit dw ?
35 base0 dw ?
36 base16 db ?
37 type db ?
38 limit16 db ?
39 base24 db ?
40 ends descr
41 macro descriptor name,typ,plevel,present,limit,gran,base
42 ;;name descr <limit and 0ffffh,base and 0ffffh,low (base shr 16),typ or plevel or present,(limit shr 16) or gran,high (base shr 16)>
43 name descr <limit and 0ffffh,base ,0 ,typ or plevel or present,(limit shr 16) or gran,0 >
44 endm
45 ; decriptor types (bit0..4 of descr.type )
46 tss386_avail = 09h
47 data_seg = 00010000b ; data segment
48 expand_down = 00000100b ; =1 limit counts down from base
49 writable = 00000010b ; =1 if write access allowed to data segment
50 code_seg = 00011000b ; code segment
51 conforming = 00000100b ; =1 code can be accesses and executed at any PL
52 readable = 00000010b ; =1 if code also can be read (cannot be ovwritten)
53 ; privilege levels (bit5..6 of descr.type )
54 priv0 = 00000000b
55 priv1 = 00100000b
56 priv2 = 01000000b
57 priv3 = 01100000b
58 ; segment present bit (bit7 of descr.type )
59 is_present = 10000000b
60 not_present = 00000000b
61 ;definition of granularity ( bits6..7 in descr.limit16 )
62 gran_byte = 00000000b
63 gran_page = 10000000b ; 4k granularity
64 use_16 = 00000000b
65 use_32 = 01000000b
67 ;****** rm32,imm16 helpers
68 macro addzx_e rm,i
69 db 66h
70 add rm,i
71 dw 0
72 endm
75 group DGROUP _TEXT,_DATA,_BSS
76 assume cs:DGROUP,ds:DGROUP
78 segment _DATA byte public use16 'DATA'
80 label gdt byte
81 gdt_null descr <?> ;0000
82 gdt_vcpi descr <?> ;0008
83 gdt_vcpi2 descr <?> ;0010
84 gdt_vcpi3 descr <?> ;0018
85 descriptor gdt_abs ,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_32),0
86 ;Note: code/data segs must be flagged use16 (i.e. use ip/sp, not eip/esp)
87 ;Note: base addrs will be fixed up in prepare_vcpi()
88 descriptor gdt_code,(code_seg+readable),priv0,is_present,0fffffh,(gran_page+use_16),0
89 descriptor gdt_data,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_16),0
90 descriptor gdt_tss ,tss386_avail ,priv0,is_present,0ffh ,gran_byte ,<offset tss>
91 SEL_VCPI = (gdt_vcpi - gdt_null)
92 SEL_TSS = (gdt_tss - gdt_null)
93 SEL_ABS = (gdt_abs - gdt_null)
94 SEL_CODE = (gdt_code - gdt_null)
95 SEL_DATA = (gdt_data - gdt_null)
97 label gdtr pword
98 gdt_lim dw 0ffffh
99 gdt_base dw offset gdt,0
101 ;Note: layout dictated by vcpi api, don't rearrange!
102 label sw2pm_params byte
103 ;Note: base addrs will be fixed up in prepare_vcpi()
104 label pagedir_laddr dword
105 sw2pm_cr3 dd 1000h
106 sw2pm_gdtr_ptr dw offset gdtr,0
107 sw2pm_idtr_ptr dw offset idtr,0
108 sw2pm_ldtr dw 0 ;we don't need it
109 sw2pm_tr dw SEL_TSS ;vcpi thinks we need it... can't set to 0
110 sw2pm_jumpaddr dd 0
111 dw SEL_CODE
113 vcpi_pm_entry dd 0
114 dw SEL_VCPI
116 label idtr pword
117 idt_lim dw 03ffh ;we won't enable ints,
118 idt_base dd 0 ; so let's leave it the same as for rm
120 ends _DATA
122 segment _BSS byte public use16 'BSS'
124 tss dd ?,? ;enough, we'll never use it anyway
126 ends _BSS
128 segment _TEXT byte public use16 'CODE'
130 ;***************************************************************
131 ;char* prepare_vcpi(void *pagebuf);
132 ;****** Return: AX=>first unused byte in pagebuf
133 ;****** Uses: Flags
134 ;***************************************************************
135 global _prepare_vcpi:near
136 global prepare_vcpi:near
137 proc _prepare_vcpi near
139 ;pop ax
140 ;pop bx ;pgbuf
141 ;push bx
142 ;push ax
143 prepare_vcpi:
145 ;Calculate pagedir/page0 addrs, initialize cr3 and pagedir[0]
146 xor eax,eax
147 ; heap_top = prepare_vcpi(malloc_or_die(8*1024+4));
148 mov cx,8*1024+4
149 extrn malloc_or_die:near
150 call malloc_or_die ;keep cx
152 mov edx,cs
153 shl edx,cl ;edx = linear addr of CS
154 mov si,offset gdt_vcpi
155 ; Fix up base of some gdt descriptors
156 ; Note: 'add [dword xx.base0],edx' actually updates 24 bit quantity!
157 ; Do NOT replace with mov!
158 mov ebx,10000h-28h
159 add [dword bx+si+sw2pm_idtr_ptr-gdt_vcpi+28h],edx
160 @@fixup:
161 add [dword bx+si+(gdt_code.base0)-gdt_vcpi+28h],edx
162 add bx,8
163 js @@fixup
164 mov bh,10h
165 add eax,edx
166 and ax,0f000h ;eax = 4k aligned linear addr of pagebuf
167 add eax,ebx ;eax=page0 linear addr
168 add [si+sw2pm_cr3-gdt_vcpi],eax
169 mov edi,eax
170 sub edi,edx
171 mov al,3 ;add present+writable bits
172 mov [bx+di],eax ;stuff it into pagedir[0]
173 push ds
174 pop es ;es:di->page0,es:di+1000h->pagedir
175 ;page directory will use only one entry (4 bytes):
176 ;cr3 => pagedir => page0 => ########
177 ; (1 entry) (1024 => # 4M #
178 ; entries)=> # page #
179 ; => ########
180 ; Return
181 lea ax,[bx+di+4]
182 extrn _heap_top:word
183 mov [_heap_top],ax
184 ;ret
186 endp _prepare_vcpi
189 ;***************************************************************
190 ;int get_vcpi_interface();
191 ;****** Return: Z - page mapping for low 640k is 1:1
192 ;****** NZ - otherwise (it's bad)
193 ;****** Uses: Flags
194 ;***************************************************************
195 global _get_vcpi_interface:near
196 proc _get_vcpi_interface near
198 ;push si di
200 ; Get and save VCPI pm interface
201 ;mov si,offset gdt_vcpi ;DS:DI => 3 GDT entries for VCPI
202 ;mov di,[si+page0_ofs-gdt_vcpi] ;ES:DI => page0
203 ;push ds
204 ;pop es
205 push di
206 mov ax,0DE01h ;get vcpi pm interface
207 int 67h
208 xchg [vcpi_pm_entry],ebx ;clear ebx
209 ;xor bx,bx
211 ; Check that mapping for low 640k is 1:1
212 pop si ; [page0_ofs]
213 ;cld
214 @@map_chk:
215 lodsd
216 shr eax,12
217 cmp ax,bx
218 jne @@bad
219 inc bx
220 cmp al,((640*1024) shr 12)-1
221 jne @@map_chk
222 ; Return
223 @@bad:
224 ret
225 endp _get_vcpi_interface
228 ;***************************************************************
229 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs);
230 ;***************************************************************
231 ;****** Copies PAGE_SIZE bytes
232 ;****** Uses: Flags
233 ;***************************************************************
234 global call_pm_routine:near
235 proc call_pm_routine near
237 arg dstofs :dword, \
238 srcseg :word, \
239 srcofs :dword = PARAM_SIZE
241 struc pm_regs
242 $$retaddr dw ?
243 $$f dw ?
244 $$edi dd ?
245 $$esi dd ?
246 $$ebp dd ?
247 $$esp dd ?
248 $$ebx dd ?
249 $$edx dd ?
250 $$ecx dd ?
251 $$eax dd ?
252 ends
254 ;***************************************************************
255 ;****** Helper: goes into 16bit pm and calls routine (addr on stk)
256 ;***************************************************************
257 mov bp,sp ; ss:bp => struct pm_regs
259 xor ax,ax ; IRET stack for return to vm
260 push ax gs ; (9 dwords)
261 push ax fs ;
262 push ax ds ;
263 push ax es ;
264 push ax ss ;
265 push ebp ; esp
266 pushfd ; eflags: IF saved here
267 push ax cs ;
268 push ax ;\eip
269 push offset @@vm_ret ;/
271 ;;mov [saved_xx],xx ;use if your vcpi trashes bp/etc
273 call switch_to_pm
275 ; Now we are in 16-bit protected mode
276 mov ax,SEL_DATA
277 mov ss,ax
278 ;;mov ds,ax
279 ;;mov es,ax
280 ;;mov fs,ax
281 ;;mov gs,ax
282 assume nothing
283 assume cs:DGROUP
285 ;;mov xx,[saved_xx] ;use if your vcpi trashes bp/etc
286 lea sp,[bp-9*4] ;else we can do this trick with bp
288 ; Call the routine (bp points to params on stack if any)
289 mov ax,[(pm_regs bp).$$f] ; ss:bp => struct pm_regs
290 mov bp,[word (pm_regs bp).$$ebp] ;ss:bp => params
291 call ax
293 ; Ok, let's return to vm
294 mov ax,0DE0Ch ; maybe we need whole eax?
295 cli ; to be safe
296 clts ;
297 push SEL_ABS ; vcpi wants ds=all_addrspace
298 pop ds ;
299 call [pword cs:vcpi_pm_entry]
300 @@vm_ret:
301 ; Now we are in vm86 mode. Sregs, esp, eflags (IF) restored from IRET stack
302 ret
304 ;***************************************************************
305 switch_to_pm:
306 assume cs:DGROUP,ds:DGROUP
307 pop [word sw2pm_jumpaddr]
308 ;mov [word sw2pm_jumpaddr+2],0
309 ;mov [word sw2pm_jumpaddr+4],SEL_CODE
310 mov esi,cs
311 shl esi,4
312 addzx_e si,<offset sw2pm_params>
313 mov ax,0DE0Ch ; vcpi: switch to pm
314 cli
315 int 67h
317 ;***************************************************************
318 ;****** Helper: This is where real copy is done
319 ;***************************************************************
320 global do_memcpy_vcpi:near
321 label do_memcpy_vcpi near
323 ; Note: ss:bp => params
324 ; Move data
325 mov ax,SEL_ABS
326 mov ds,ax
327 mov es,ax
328 assume nothing
329 assume cs:DGROUP
331 ; Set up target addr:
332 ; replace page mapping for page at 0 so
333 ; that it points to dstofs
334 mov eax,[dstofs]
335 mov al,03h ; writeable, present
336 call @@set_mapping
337 ;push eax ;X we'll need to restore mapping...
338 xor edi,edi ;es:edi => remapped page
340 ; Set up source addr
341 mov esi,[srcofs]
343 ; Do copying
344 xor ecx,ecx
345 mov ch,4096/256
346 ;cld
347 ;; cmp esi,edi
348 ;; jae @@do_copy
349 ;; add esi,ecx ;src<dst: we must do
350 ;; dec esi ; copy backwards to avoid
351 ;; add edi,ecx ; overwrite bug
352 ;; dec edi ;
353 ;; std ;
354 ;;@@do_copy:
355 db 67h ;address width override for esi/edi
356 rep movsb
357 ;; cld
359 ; Restore page mapping for page at 0
360 ;pop eax ;X
361 @@set_mapping:
362 mov esi,[cs:sw2pm_cr3]
363 xchg [esi-1000h],eax ; restore page0[0]
364 mov ecx,cr3 ; reload TLB cache
365 mov cr3,ecx ;
366 ; Return
367 vcpi_ret:
368 ret
370 endp call_pm_routine
371 assume cs:DGROUP,ds:DGROUP
374 ;***************************************************************
375 ;void _vm2rm();
376 ;***************************************************************
377 ;****** Uses: Flags
378 ;***************************************************************
379 global _vm2rm:near
380 proc _vm2rm near
382 p8086
383 extrn _vcpi:byte
384 test [_vcpi],-1
385 jz vcpi_ret
386 p386
387 pop ax
388 push cs ;*
389 push ax
390 push si
391 push ds
392 extrn sssp:word
393 mov [sssp],sp
394 mov [sssp+2],ss
396 call switch_to_pm
398 ; Now we are in 16-bit protected mode
399 mov ax,SEL_DATA ; load data sregs with limit >=64k
400 mov ss,ax ; or you may get limit violations
401 mov ds,ax ; later in rm
402 ;mov es,ax ; (actually I prefer 4gig limits :-)
403 ;mov fs,ax ;
404 ;mov gs,ax ;
406 ; Black magic here
407 mov eax,cr0
408 and eax,7ffffffeh ; clear PG,P bits
409 mov cr0,eax ; look mommy, we're in rm now!
410 mov cr3,eax ; flush TLB cache
412 ; Now we are in rm, but not yet: have to restore sregs:
413 lss sp,[dword sssp]; SS
414 pop ds ; DS
415 pop si
416 retf ; CS
418 endp _vm2rm
420 ends _TEXT
422 end
424 ;###### END OF FILE ############################################